Überschreibmodus für Textboxen II Eine erweiterte TextBox-Klasse mit einer neuen Eigenschaft "OverwriteMode".
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  10.876
www.tools4vb.de	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 3 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

In Standard-Textboxen gibt es bekanntlich keinen Überschreibmodus. Viele sind es aber gewohnt, über die Einfg-Taste vom Einfügemodus in den Überschreibmodus und umgekehrt umzuschalten. Wie man dieses Feature in seinen eigenen Anwendungen bereitstellen kann, zeigt der nachfolgende Tipp.

Wie funktioniert der Überschreibmodus? Genau - wir tun so, als wäre beim Drücken einer Taste das aktuelle Zeichen, vor dem sich der Eingabecursor befindet, markiert - so als hätten wir vorher über die Umsch und der rechten Pfeiltaste eben dieses Zeichen hervorgehoben. Denn wie wir alle wissen, wird ein markierter Textausschnitt beim Drücken einer Taste durch das entsprechende Zeichen ersetzt.

Halt! Wir müssen uns ja noch merken, ob der Einfüge- oder der Überschreibmodus eingeschaltet ist. Am einfachsten wir erstellen uns hierzu eine von der Standard TextBox abgeleitete Klasse mit einer neuen Eigenschaft OverwriteMode.

Und hier der Code unserer neuen TextBox-Klasse

Public Class TextBoxEx
  Inherits TextBox

  ' API-Deklarationen zur Manipulation des Eingabecursors
  Private Declare Function CreateCaret Lib "user32" ( _
    ByVal hwnd As IntPtr, _
    ByVal hBitmap As Int32, _
    ByVal nWidth As Int32, _
    ByVal nHeight As Int32) As Int32
 
  Private Declare Function ShowCaret Lib "user32" ( _
    ByVal hwnd As IntPtr) As Int32
 
  Private Sub SetNewCaret(ByVal hWnd As IntPtr, ByVal nWidth As Int32, ByVal nHeight As Int32)
    CreateCaret(hWnd, 0, nWidth, nHeight)
    ShowCaret(hWnd)
  End Sub

  ''' <summary>
  ''' Zeigt den Cursor normal bzw. als Block an
  ''' </summary>
  Private Sub SetCursor()
    If OverwriteMode = True Then
      ' Cursor breiter darstellen
      SetNewCaret(Me.Handle.ToInt32, 7, 13)
    Else
      ' Cursor normal darstellen
      SetNewCaret(Me.Handle.ToInt32, 1, 13)
    End If
  End Sub

  Private _OverwriteMode As Boolean
 
  ''' <summary>
  ''' Legt fest, ob der Überschreibmodus aktiviert ist oder nicht.
  ''' </summary>
  Public Property OverwriteMode() As Boolean
    Get
      Return _OverwriteMode
    End Get
    Set(ByVal value As Boolean)
      _OverwriteMode = value
 
      ' Cursor korrekt darstellen
      If Me.Focused Then SetCursor()
    End Set
  End Property

  Private Sub TextBoxEx_GotFocus(ByVal sender As Object, _
    ByVal e As System.EventArgs) Handles Me.GotFocus
 
    ' Cursor korrekt darstellen
    SetCursor()
  End Sub

  Private Sub TextBoxEx_KeyDown(ByVal sender As Object, _
    ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
 
    If e.KeyCode = Keys.Insert Then
      ' INSERT schaltet den Überschreibmodus automatisch ein/aus
      OverwriteMode = Not OverwriteMode
    End If
  End Sub

  Private Sub TextBoxEx_KeyPress(ByVal sender As Object, _
    ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles Me.KeyPress
 
    With CType(sender, TextBox)
      ' Falls Überschreibmodus aktiviert...
      If _OverwriteMode AndAlso Asc(e.KeyChar) > 31 AndAlso .SelectionLength = 0 Then
        ' ... aktuelles Zeichen überschreiben
        .SelectionLength = 1
      End If
    End With
  End Sub

End Class