VB6 Command$ mit Unicode Unterstützung Parameterübergabe an ein VB6 Programm unicodefähig machen
Autor:   Ralf Schlegel	Bewertung:     [ Jetzt bewerten ]	Views:  8.667
www.vb-zentrum.de	System:  Win9x, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Geben Sie hier Ihre persönliche Bewertung ab! Bisher wurde noch keine Bewertung abgegeben.

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Wenn Sie in Ihrem VB6 Programm die Parameterübergabe nutzen, so greifen Sie einfach auf "Command$" zu. Diese VBA-interne Funktion unterstützt aber kein Unicode. Um Ihre EXE mit unicodefähigen Parametern zu versorgen hilft wieder einmal das Microsoft API mit den Funktionen "GetCommandLineW" und "PathGetArgsW" weiter.

Da eine solche Parameterübergabe nur zur Laufzeit vorkommen darf, und auch nur dann, wenn unsere Anwendung auf einem unicodefähigen Betriebssystem läuft, müssen wir die Verwendung der Funktion um diese 2 Abfragen erweitern; so ist der Code von Windows 95 bis heute uneingeschränkt nutzbar und 100% kompatibel zum Original.

Unsere neue Funktion nennen wir ebenfalls "Command"! Dadurch wird die VBA Funktion gewissermaßen überschrieben und wir brauchen an unserem Programmcode keine weiteren Änderungen durchzuführen. Wird die Originalfunktion dennoch benötigt, so läßt sie sich explizit mit "VBA.Command" aufrufen (siehe Beispielcode):

Private Declare Function GetCommandLineW Lib "kernel32" () As Long
Private Declare Function PathGetArgsW Lib "shlwapi" ( _
  ByVal pszPath As Long) As Long
Private Declare Function SysReAllocString Lib "oleaut32" ( _
  ByVal pbString As Long, _
  ByVal pszStrPtr As Long) As Long
 
Private Declare Function GetVersionExA Lib "kernel32" ( _
  lpVersionInformation As OSVERSIONINFO) As Long
 
Private Type OSVERSIONINFO
  dwOSVersionInfoSize As Long
  dwMajorVersion As Long
  dwMinorVersion As Long
  dwBuildNumber As Long
  dwPlatformId As Long
  szCSDVersion As String * 128
End Type
 
Private Const VER_PLATFORM_WIN32_NT = 2

Public Function command() As String
  If isSystemNT And Not isIDE Then
    SysReAllocString VarPtr(command), PathGetArgsW(GetCommandLineW)
  Else
    command = VBA.command$
  End If
End Function

' Hilfsfunktionen:
Private Function isSystemNT() As Boolean
  Dim info As OSVERSIONINFO
 
  info.dwOSVersionInfoSize = Len(info)
  GetVersionExA info
  isSystemNT = (info.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
 
Private Function isIDE() As Boolean
  isIDE = (App.LogMode = 0)
End Function