vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Schützen Sie Ihre Software vor Software-Piraterie - mit sevLock 1.0 DLL!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Grafik und Font · Bilder und Icons   |   VB-Versionen: VB2005 - VB201501.03.17
Daten im Form-Icon anzeigen

Dieser Tipp realisiert die Anzeige von Daten (Text, numerisch) im Icon einer Form während der Laufzeit auch in der Taskbar

Autor:   Dietrich HerrmannBewertung:     [ Jetzt bewerten ]Views:  6.508 
ohne HomepageSystem:  Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Möglicherweise kennt ihr die Anzeige von WhatsApp, wenn neue Posts beim Messenger eingetroffen sind. Es wird dann im Icon die Anzahl der neuen Posts mitgeteilt.

Dieses Prinzip kann man mit diesem Tipp auch für Forms sozusagen nachbilden.

Als erstes muss das WindowsAPICodepack heruntergeladen und installiert werden:
 https://github.com/dbarros/WindowsAPICodePack

Dann die hier angeführten Verweise (Assemblies) dem eigenen Projekt hinzufügen:

  • Microsoft.WindowsAPICodePack
  • Microsoft.WindowsAPICodePack.Shell
  • PresentationCore
  • PresentationFramework
  • WindowsBase

In der Anwendung treffen wir dann folgende Vereinbarungen:

' Icon zum Zwischenspeichern des Original-Icons
Dim iIcon As Icon
 
' Bitmap zur Aufnahme des Form-Icons
Dim bmpIco As Bitmap 
 
' Graphics der Bitmap
Dim gr As Graphics   
 
' der Font für die Textausgabe
Dim FontIco As New Font("MS Sans Serif", 8, Font.Style.Bold)

Der Font sollte natürlich recht klein sein, denn das Icon wird bspw. in der Taskbar auch recht klein angezeigt.

Im Form_Load-Ereignis müssen noch Vorbereitungen getroffen werden für das Aktualisieren des Icons in der Taskbar.

Icon = My.Resources.VIP3_IP_8 ' Icon der Form setzen
iIcon = Icon ' Original-Icon zwischenspeichern
If Not TaskbarManager.IsPlatformSupported Then
  MessageBox.Show("Overlay Icon is not supported by your OS!")
  Application.Exit()
End If
TaskbarManager.Instance.ApplicationId = "SerienMails"
TaskbarManager.Instance.SetApplicationIdForSpecificWindow(Me.Handle, "MailsForm")

Für die Realisierung werden folgende drei Funktionen verwendet:

''' <summary>
''' Text in Icon schreiben
''' </summary>
''' <param name="ico">das betreffende Icon</param>
''' <param name="theFont">der Font</param>
''' <param name="theBGColor">die Hintergrundfarbe</param>
''' <param name="theBorderColor">die Randfarbe, ist gleichzeitig Textfarbe</param>
''' <param name="theBorderWidth">die Randbreite</param>
''' <param name="theValue">der Wert, Text</param>
''' <param name="theRectAlign">die Position des Ausgaberechtecks</param>
Public Function ChangeAppIcon(ico As Icon, theFont As Font, theBGColor As Color, _
  theBorderColor As Color, theBorderWidth As Short, _
  theValue As Short, Optional theRectAlign As String = "ul") As Icon
 
  ' das Form-Icon als Bitmap
  Dim bmpIco As Bitmap = ico.ToBitmap
  Dim gr As Graphics = Graphics.FromImage(bmpIco)
 
  ' Textgröße messen
  Dim fs As Size = TextRenderer.MeasureText(theValue.ToString, theFont)
  fs = New Size(fs.Width + theBorderWidth * 2, fs.Height + theBorderWidth * 2)
 
  ' Rechteck des Texts festlegen
  Dim tRect As New Rectangle(New Point(0, 0), fs) 
 
  ' Rechteck des Icons
  Dim bRect As New Rectangle(New Point(0, 0), New Size(bmpIco.Size)) 
 
  ' passt Ausgaberechteck ins Icon-Rechteck?
  Dim b As Boolean = bRect.Contains(tRect) 
  If Not b Then Exit Function
 
  ' Stift für den Rand definieren
  Dim pen As New Pen(theBorderColor, theBorderWidth) 
  pen.Alignment = PenAlignment.Inset
  Dim sf As New StringFormat
  sf.LineAlignment = StringAlignment.Center ' Ausrichtung des Texts
  sf.Alignment = StringAlignment.Center
  tRect.Location = CalcNewPositionPoint(bRect, _
    tRect, theRectAlign) ' das Ausgaberechteck postionieren
  With gr
    ' Rechteck ausfüllen mit Hintergrundfarbe
    .FillRectangle(New SolidBrush(theBGColor), tRect)
    'Rechteck-Rand zeichnen
    If theBorderWidth> 0 Then .DrawRectangle(pen, tRect)
    ' den Text ins Rechteck schreiben
    .DrawString(Trim(theValue.ToString), theFont, New SolidBrush(theBorderColor), tRect, sf)
  End With
  Return ConvBMPtoICO(bmpIco, bmpIco.Size) ' neues Form-Icon speichern
End Function
''' <summary>
''' Positionieren eines Rechtecks auf einem 'Hintergrund'-Rechteck
''' </summary>
''' <param name="theOrigCoords">die Koordinaten des Hintergrundrechtecks</param>
''' <param name="theObjCoords">die Koordinaten des zu positionierenden Rechtecks</param>
''' <param name="theAlignment">die Ausrichtung des zu pos. Rechtecks</param>
''' <returns>die neue Location des zu pos. Rechtecks</returns>
Private Function CalcNewPositionPoint(ByVal theOrigCoords As Rectangle, _
  ByVal theObjCoords As Rectangle, ByVal theAlignment As String) As Point
 
  Dim x As Short = theOrigCoords.X
  Dim y As Short = theOrigCoords.Y
 
  ' Position (Koordinaten) ermitteln
  With theObjCoords
    Select Case theAlignment
      Case "z" ' zentrieren
        x = theOrigCoords.Left + (theOrigCoords.Width - .Width) / 2
        y = theOrigCoords.Top + (theOrigCoords.Height - .Height) / 2
      Case "ol"   ' oben links
        x = theOrigCoords.Left
        y = theOrigCoords.Top
      Case "or"  ' oben rechts
        x = theOrigCoords.Right - .Width
        y = theOrigCoords.Top
      Case "ul"   ' unten links
        x = theOrigCoords.Left
        y = theOrigCoords.Bottom - .Height
      Case "ur"  ' unten rechts
        x = theOrigCoords.Right - .Width
        y = theOrigCoords.Bottom - .Height
    End Select
    ' Rechteck neu positionieren
    .Location = New Point(x, y)
  End With
  Return theObjCoords.Location
End Function
''' <summary>
''' Konvertieren Bitmap in Icon
''' </summary>
''' <param name="theBMP">die Original-Bitmap</param>
''' <param name="theSize">die neue Größe des Icon</param>
''' <returns>das Icon</returns>
Public Function ConvBMPtoICO(ByVal theBMP As Image, ByVal theSize As Size) As Icon
  Dim bitmap As New Bitmap(theSize.Width, theSize.Height)
  bitmap = theBMP
  Return Icon.FromHandle(bitmap.GetHicon())
End Function

Die erste Funktion realisiert das Erstellen eines Rechtecks mit Rand, in das der gewünschte Text geschrieben wird. Es wird geprüft, ob das zu schreibende Rechteck ins Icon-Rechteck passt. Wenn nicht, wird es einfach nicht gezeichnet. Das ist die Trivial-Lösung; diese Überprüfung ist eventuell noch ausbaufähig...

Dieses Rechteck kann mittels der zweiten Funktion im Icon nach 5 Varianten postioniert werden (siehe Code).

Anwendung:
Ich habe diese Funktion bspw. in einer Schleife angewendet (stelle sie mal hier symbolisch dar):

For i As Short = 1 To 15
  ' Icon ändern mittels Funktion
  Me.Icon = ChangeAppIcon(Me.Icon, FontIco, Color.Red, Color.White, 2, i)
  ' Icon in der Taskbar aktualisieren
  TaskbarManager.Instance.SetOverlayIcon(Me.Icon, i.ToString)
Next 
 
Me.Icon = iIcon

Damit erreiche ich, dass im Icon in der Taskbar die Zählung (Werte von i) während des Durchlaufs in der gewünschten Form angezeigt werden.
Am Ende der Schleife sollte das Original-Icon wieder angezeigt werden!

Dieser Tipp wurde bereits 6.508 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel