vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik:    |   VB-Versionen: VB5, VB601.12.05
Verändern der Spaltenbreite im ListView-Control verhindern

Per Subclassing lässt sich das interaktive Verändern der Spaltenbreiten im ListView-Control durch den Anwender gezielt für einzelne oder alle Spalten verhindern.

Autor:  Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  1.386 
http://www.tools4vb.de/System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt 

Das ListView-Control gehört sicherlich zu einem der meist verwendeten Controls in der eigenen VB-Anwendung. Verwendet man das ListView-Control im Report-Modus (Detail-Ansicht) kann der User die Spaltenbreiten zur Laufzeit individuell anpassen. Manchmal möchte man aber genau das unterbinden. Leider verfügt das ListView-Control über keine eigene Eigenschaft, um das Ändern der Spaltenbreiten zu verhindern. Mit nachfolgendem Tipp lässt sich das aber mit relativ wenig Aufwand "nachrüsten".

Um das Ändern der Spaltenbreite zur Laufzeit zu verhindern, müssen wir das ListView-Control "subclassen", d.h. wir müssen die Fensternachrichten abfangen. Hierbei haben wir dann sogar die Möglichkeit nur auf ganz bestimmte Spalten zu reagieren, d.h. der Anwender kann bspw. die ersten beiden Spalten im ListView-Control nicht verändern, alle anderen Spalten jedoch individuell einstellen.

Erstellen Sie ein neues Projekt und platzieren auf die Form ein ListView-Control. Fügen Sie nachfolgenden Code in den Codeteil der Form1 ein:

Option Explicit
 
Private Sub Form_Load()
  Dim i As Long
  Dim u As Long
 
  With ListView1
    ' Spalten erstellen
    With .ColumnHeaders
      For i = 1 To 5
        .Add , , "Spalte " & CStr(i)
      Next i
    End With
 
    ' Ansicht einstellen
    .View = lvwReport
    .FullRowSelect = True
 
    ' Testdaten eintragen
    For i = 1 To 10
      With .ListItems.Add(, , "Eintrag " & CStr(i))
        For u = 1 To 4
          .SubItems(u) = "Wert " & CStr(u)
        Next u
      End With
    Next i
  End With
 
  ' Subclassing starten
  StartSubclass ListView1
End Sub
Private Sub Form_Unload(Cancel As Integer)
  ' Wichtig! Das Subclassing muss ordnungegemäß
  ' wieder ausgeschaltet werden!!!
  EndSubclass
End Sub

Fügen Sie dem Projekt ein neues Modul mit folgendem Code hinzu:

Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function SetWindowLong Lib "user32" _
  Alias "SetWindowLongA" ( _
  ByVal hWnd As Long, _
  ByVal nIndex As Long, _
  ByVal dwNewLong As Long) As Long
 
Private Declare Function CallWindowProc Lib "user32" _
  Alias "CallWindowProcA" ( _
  ByVal lpPrevWndFunc As Long, _
  ByVal hWnd As Long, _
  ByVal Msg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
Public Declare Sub CopyMemory Lib "kernel32" _
  Alias "RtlMoveMemory" ( _
  pDest As Any, _
  pSource As Any, _
  ByVal dwLength As Long)
 
Private Const WM_NOTIFY = &H4E
Private Const GWL_WNDPROC = -4
 
Private nOldWndProc As Long
Private nHWnd As Long
 
Private Type NMHDR
  hwndFrom As Long
  idFrom As Long
  code As Long
End Type
 
Private Type NMHEADER
  hdr As NMHDR
  iItem As Long
  iButton As Long
  pitem As Long
End Type
 
' Nachrichten-Konstanten
Private Const HDN_FIRST = -300&
Private Const HDN_DIVIDERDBLCLICK = (HDN_FIRST - 5)
Private Const HDN_BEGINTRACK = (HDN_FIRST - 6)
Public Sub StartSubclass(oListView As Object)
  ' Subclassing starten
  nHWnd = oListView.hWnd
  nOldWndProc = SetWindowLong(nHWnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub
Public Function WindowProc(ByVal hWnd As Long, ByVal uMsg As Long, _
  ByVal wParam As Long, ByVal lParam As Long) As Long
 
  Dim oMsg As NMHDR
  Dim oHeader As NMHEADER
 
  Select Case uMsg
    Case WM_NOTIFY
      ' Message-Struktur füllen
      Call CopyMemory(oMsg, ByVal lParam, Len(oMsg))
 
      Select Case oMsg.code
        Case HDN_BEGINTRACK, HDN_DIVIDERDBLCLICK
          ' Header-Struktur füllen
          Call CopyMemory(oHeader, ByVal lParam, Len(oHeader))
 
          ' ---------------------------------------------------------------
          ' oHeader.iItem enhtält den Spalten-Index des ListView-Headers
          ' Sollen nur bestimmte Spalten in ihrer Breite nicht verändert
          ' werden dürfen, einfach oHeader.iItem abfragen
          ' 
          ' Beispiel:
          ' Select Case oHeader.iItem
          '   Case 0, 1     ' Spalte 1 und 2 dürfen nicht verändert werden
          '     WindowProc = 1
          '     Exit Function
          '   Case Else     ' alle anderen Spalten dürfen verändert werden
          ' End Select
          ' ---------------------------------------------------------------
 
          ' falls, keine Spalte verändert werden darf...
          WindowProc = 1
          Exit Function
      End Select
  End Select
 
  ' Alle anderen Windows-Nachrichten an das Objekt weiterleiten
  WindowProc = CallWindowProc(nOldWndProc, hWnd, uMsg, wParam, lParam)
End Function
Public Sub EndSubclass()
  ' Subclassing beenden
  Call SetWindowLong(nHWnd, GWL_WNDPROC, nOldWndProc)
End Sub