Wie speichere ich den Inhalt einer TextBox und lese diesen dann wieder aus? VB-Version:  VB5, VB6
	Views:  10.974

Es gibt - wie so oft - mehrere Möglichkeiten, den Inhalt einer TextBox zu speichern.

Möglichkeit 1: Speichern in eine Textdatei

Dim F As Integer
F = FreeFile
Open "DeineDatei.txt" For Output As #F
Print #F, "Dein Text Zeile 1"
Print #F, "Dein Text Zeile 2"
...
' oder
Print #F, Text1.Text
...
Close #F

' Lesen des Datei-Inhalts
Dim F As Integer
Dim Zeile1 As String
Dim Zeile2 As String
 
F = FreeFile
Open "DeineDatei.txt" For Input As #F
Line Input #F, Zeile1
Line Input #F, Zeile2
...
Close #F

' Einer Textbox zuordnen
Text1.Text = Zeile1
Text2.Text = Zeile2

Möglichkeit 2: Speichern in eine INI-Datei

' INI-Dateien lesen/schreiben
Private Declare Function WritePrivateProfileString Lib "kernel32" _
  Alias "WritePrivateProfileStringA" ( _
  ByVal lpApplicationName As String, _
  ByVal lpKeyName As Any, _
  ByVal lpString As Any, _
  ByVal lpFileName As String) As Long
 
Private Declare Function GetPrivateProfileInt Lib "kernel32" _
  Alias "GetPrivateProfileIntA" ( _
  ByVal lpApplicationName As String, _
  ByVal lpKeyName As String, _
  ByVal nDefault As Long, _
  ByVal lpFileName As String) As Long
 
Private Declare Function GetPrivateProfileString Lib "kernel32" _
  Alias "GetPrivateProfileStringA" ( _
  ByVal lpApplicationName As String, _
  ByVal lpKeyName As Any, _
  ByVal lpDefault As String, _
  ByVal lpReturnedString As String, _
  ByVal nSize As Long, _
  ByVal lpFileName As String) As Long

' Text (String) aus INI-Datei lesen
Public Function GetIniString(ByVal Sektion As String, ByVal Titel As String, _
   ByVal Vorgabe As String, ByVal Länge As Integer, _
   ByVal setupFile As String) As String
 
  Dim Result As Long
  Dim Dummy As String
 
  Dummy = Space$(Länge + 1)
  Result = GetPrivateProfileString(Sektion, Titel, Vorgabe, Dummy, Länge, setupFile)
  GetIniString = Left$(Dummy, Result)
End Function

' Text (String) in INI-Datei speichern 
Public Sub WriteIniString(ByVal Sektion As String, ByVal Titel As String, _
   ByVal IniString As String, ByVal setupFile As String)
   Dim Result As Long
 
   Result = WritePrivateProfileString(Sektion, Titel, IniString, setupFile)
End Sub

Möglichkeit 3: Speichern in die Windows-Registrier-Datenbank

' Text (String) in Registry speichern
SaveSetting "myProgram", "User1", "Name", txtName.Text
SaveSetting "myProgram", "User1", "EMail", txtMail.Text

' Text (String) aus Registry auslesen
txtName.Text = GetSetting("myProgram", "User1", "Name")
txtMail.Text = GetSetting("myProgram", "User1", "Email")