Dim _dvCustomers As DataView
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
 
        SqlDataAdapter1.Fill(DataSet11.Customers)
        SqlDataAdapter2.Fill(DataSet11.Orders)
 
        DataGrid1.TableStyles.Add(BuildColumns(DataSet11.Customers, Nothing, _
          Nothing))
        DataGrid1.TableStyles.Add(BuildColumns(DataSet11.Orders, Nothing, _
        Nothing))
        ChildRelation()
 
    End Sub
 
    Private Sub ChildRelation()
 
        Dim dr As DataRelation
        dr = New DataRelation("CustomersOrders", _
          DataSet11.Customers.CustomerIDColumn, _
          DataSet11.Orders.CustomerIDColumn)
        DataSet11.Customers.ChildRelations.Add(dr)
 
        _dvCustomers = DataSet11.Customers.DefaultView
 
        DataGrid1.DataSource = _dvCustomers
 
    End Sub
 
    ' Build columns
    Private Function BuildColumns(ByVal dt As DataTable, ByVal includeColumns() _
      As String, ByVal excludeColumns() As String) As DataGridTableStyle
        Dim ts As New DataGridTableStyle
        Dim txtCol As DataGridTextBoxColumn
        Dim boolCol As DataGridBoolColumn
 
        ts.MappingName = dt.TableName
        'ts.MappingName = "xx1z"
 
        For Each dc As DataColumn In dt.Columns
            Dim include As Boolean = True
            If Not includeColumns Is Nothing Then
                include = Array.IndexOf(includeColumns, dc.ColumnName) > -1
            End If
            If Not excludeColumns Is Nothing Then
                include = include AndAlso Array.IndexOf(excludeColumns, _
                  dc.ColumnName) = -1
            End If
 
            If include Then
                Dim dgc As DataGridColumnStyle
 
                Select Case True
                    Case dc.DataType Is GetType(System.Boolean)
                        boolCol = New DataGridBoolColumn
                        dgc = boolCol
                        boolCol.Alignment = HorizontalAlignment.Right
                    Case dc.DataType Is GetType(System.DateTime)
                        txtCol = New DataGridTextBoxColumn
                        dgc = txtCol
                        txtCol.Alignment = HorizontalAlignment.Right
                        txtCol.Format = "g"
                        txtCol.Width = 100
                    Case dc.DataType Is GetType(System.String)
                        txtCol = New DataGridTextBoxColumn
                        dgc = txtCol
                        txtCol.Alignment = HorizontalAlignment.Center
                        txtCol.Width = dc.MaxLength
                    Case Else
                        txtCol = New DataGridTextBoxColumn
                        dgc = txtCol
                        txtCol.Alignment = HorizontalAlignment.Right
                End Select
 
                dgc.MappingName = dc.ColumnName
                dgc.HeaderText = dc.Caption
 
                ts.GridColumnStyles.Add(dgc)
            End If
        Next
 
        Return ts
    End Function