''' <summary>Die Routine prüft ggf. Gif. Bei einem GDI+Framefehler wird der
''' erste verfügbare Frame (oder Nothing) zurückgegeben, sonst das gegebene 
''' Frame</summary>
''' <param name="img">das zu prüfende Bild</param>
Private Function CheckImage(ByVal img As Image) As Image
 
   'Picturebox verliert Displayfähigkeit, wenn animierte GIFs mit
   'fehlerhaften (?) Frames angezeigt werden sollen
 
   If Not img.RawFormat.Equals(Imaging.ImageFormat.Gif) Then Return img
 
   Dim fc As Integer = img.GetFrameCount(Imaging.FrameDimension.Time)
 
   Dim frame As Image = Nothing, ok As Boolean = True
 
   For i As Integer = 0 To fc - 1
      Try
         If img.SelectActiveFrame(Imaging.FrameDimension.Time, i) = 0 Then
            If frame Is Nothing Then
               frame = New Bitmap(img)
 
               Using g As Graphics = Graphics.FromImage(frame), _
                  br As New SolidBrush(Color.Red), _
                  brb As New SolidBrush(Color.White)
 
                  Dim f As New Font("Arial", 8)
                  Dim t As String = "GIF anim." & vbNewLine & "blocked"
                  Dim sz As SizeF = g.MeasureString(t, f)
 
                  g.FillRectangle(brb, 2, 2, sz.Width + 2, sz.Height + 2)
                  g.DrawString(t, f, br, 2, 2)
               End Using
            End If
         End If
      Catch ex As Exception
         ok = False
      End Try
 
      If Not ok And frame IsNot Nothing Then Return frame
   Next i
 
   If ok Then Return img 'Alle Frames sind verfügbar
   Return frame
End Function