Imports System.Windows.Forms
Imports System.Drawing
 
 
Public Class LinePanel
    Inherits Panel
 
    Private LineColor As Color = Color.Black 'Default
 
 
    Public Sub New()
        MyBase.new()
        Me.Size = New Size(100, 5)
        Me.BackColor = Color.White
    End Sub
 
 
    Protected Overrides Sub OnPaintBackground _
        (e As System.Windows.Forms.PaintEventArgs)
 
        MyBase.OnPaintBackground(e)
 
        If Me.Width < 5 Or Me.Height < 5 Then Exit Sub
 
        'Linie im Hintergrund zeichnen
        Dim pt1, pt2 As Point
        GetLinePoints(pt1, pt2)
        Using p As New Pen(LineColor, 2)
            e.Graphics.DrawLine(p, pt1, pt2)
        End Using
    End Sub
 
 
    Protected Overrides Sub OnMouseDown _
        (e As System.Windows.Forms.MouseEventArgs)
 
        MyBase.OnMouseDown(e)
 
        If e.Button = MouseButtons.Right Then
            If Me.Width < 8 Or Me.Height < 5 Then Exit Sub
 
            Dim pt1, pt2 As Point
            GetLinePoints(pt1, pt2)
 
            'Bereich der zu zeichnenden Line
            Dim rc As New Rectangle _
                (pt1.X, pt1.Y - 1, pt2.X - pt1.X, 3)
 
            If rc.Contains(e.Location) Then
                'Dialog für Linienfarbe 
                'falls auf die Panel-Linie geclickt worden ist
                Using cd As New ColorDialog
                    cd.Color = LineColor
                    If cd.ShowDialog = DialogResult.OK Then
                        LineColor = cd.Color
                        Me.Invalidate(rc) 'Linie neu zeichnen
                    End If
                End Using
            End If
        End If
    End Sub
 
 
    Private Sub GetLinePoints(ByRef pt1 As Point, ByRef pt2 As Point)
        'Position der Line - Anfangs- und Endpunkt 
        pt1 = New Point(3, Me.Height \ 2)
        pt2 = New Point(Me.Width - 3, Me.Height \ 2)
    End Sub
End Class