Option Explicit
 
' API stuff
 
' Clipboard routines.
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function RegisterClipboardFormat Lib "user32" Alias _
  "RegisterClipboardFormatA" (ByVal lpString As String) As Long
Private Declare Function SetClipboardData Lib "user32" (ByVal wFormat As Long, _
ByVal hMem As Long) As Long
 
' Global memory routines. (Pointers)
Private Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, _
  ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As _
  Long
Private Declare Sub MoveMemory Lib "kernel32" Alias "RtlMoveMemory" (ByRef _
Destination As Any, ByRef Source As Any, ByVal Length As Long)
 
' Global Memory Flags
Private Const GMEM_MOVEABLE = &H2
Private Const GMEM_ZEROINIT = &H40
Private Const GHND = (GMEM_MOVEABLE Or GMEM_ZEROINIT)
 
' Register Clipboard Format
Private Const CFSTR_PREFERREDDROPEFFECT As String = "Preferred DropEffect" & _
  vbNullChar
 
' DropEffect constants
Public Enum KdFileDropEffectConstants
    kdDropEffectNone = vbDropEffectNone
    kdDropEffectCopy = vbDropEffectCopy
    kdDropEffectMove = vbDropEffectMove
    kdDropEffectLink = 4
End Enum
 
' Copy the "DropEffect" into the clipboard. Return True if we succeed.
Public Function SetFilesDropEffect(ByVal lEffect As Long) As Boolean
 
    Dim lMemoryHandle As Long
    Dim lMemoryPointer As Long
    Dim lFormat As Long
    Dim lReturn As Long
 
    ' Open the clipboard.
    If OpenClipboard(0) Then
 
        ' Get global memory pointer to hold the lEffect variable
        lMemoryHandle = GlobalAlloc(GHND, Len(lEffect))
 
        ' If we have a memory handle
        If lMemoryHandle Then
 
            ' Lock the memory while we initialize it.
            lMemoryPointer = GlobalLock(lMemoryHandle)
 
            ' Copy the lEffect variable into the global memory.
            Call MoveMemory(ByVal lMemoryPointer, lEffect, Len(lEffect))
 
            ' Unlock the memory
            Call GlobalUnlock(lMemoryHandle)
 
            ' Register the format
            lFormat = RegisterClipboardFormat(CFSTR_PREFERREDDROPEFFECT)
 
            ' Copy the format to the clipboard.
            lReturn = SetClipboardData(lFormat, lMemoryHandle)
 
            ' Check if we succeed
            If lReturn Then
                SetFilesDropEffect = True
            End If
        End If
 
        ' Close the clipboard.
        Call CloseClipboard
 
    End If
 
End Function

    Call SetFileDropEffect(kdDropEffectCopy Or kdDropEffectLink)

    Call SetFileDropEffect(kdDropEffectMove)