Private Sub CB_Berechnen_Click()
 
Dim a#, b#, c#, p#, q#, diskr#, x1#, x2#
Const eps# = 0.0000001
 
On Error GoTo Fehler
 
If Not IsNumeric(tb_a.Text) Or Not IsNumeric(tb_b.Text) Or _
Not IsNumeric(tb_c.Text) Then _
MsgBox ("Unzulässige oder fehlende Eingabe(n)"): Exit Sub
 
a = CDbl(tb_a.Text): b = CDbl(tb_b.Text): c = CDbl(tb_c.Text)
If Abs(a) < eps Then MsgBox ("a: ungleich 0 eingeben"): Exit Sub
 
p = b / a: q = c / a
 
 
'Determinante berechnen
diskr = (p / 2) * (p / 2) - q
'Fallunterscheidung durchführen und Lösung berechnen
If diskr < -eps Then
   lb_Result.Caption = "Keine reelle Lösung (neg. Diskriminante)"
ElseIf Abs(diskr) <= eps Then
   lb_Result.Caption = CStr(Round(-p / 2, 4))
Else
   x1 = -p / 2 + Sqr(diskr)
   x2 = -p / 2 - Sqr(diskr)
   'Lösungen gerundet in ein "Lösungslabel" übertragen
   lb_Result.Caption = CStr(Round(x1, 4)) & "      " & CStr(Round(x2, 4))
 
   'Kontrollrechnung (optional)
   If Abs(x1 ^ 2 * a + x1 * b + c) > 2# * eps Then Stop
   If Abs(x2 ^ 2 * a + x2 * b + c) > 2# * eps Then Stop
End If
 
Exit Sub
 
Fehler:
MsgBox "Fehler ist aufgetreten" & vbCrLf & Err.Description
 
End Sub