Public Class frmBlink
 
    Dim WithEvents pb As New PictureBox With _
        {.Parent = Me, .Size = New Size(300, 300)}
 
    Dim WithEvents lbo As New ListBox With _
        {.Parent = Me, .Top = 330, .Width = 300, .Height = 60}
 
    Dim WithEvents tim As New Timer With _
        {.Interval = 300, .Enabled = True}
 
    Dim swap As Boolean
 
 
    Private Sub frmBlink_Load(sender As System.Object, _
                            e As System.EventArgs) Handles MyBase.Load
 
        Me.Size = New Size(320, 440)
 
        'Die Listenindices definieren die Position 
        'der Kreise in der Picturebox pb
        lbo.Items.AddRange _
           ({"100,100", "130, 130", "160, 160", "100, 160"})
 
    End Sub
 
 
    Private Sub tim_Tick(sender As Object, _
        e As System.EventArgs) Handles tim.Tick
 
        swap = Not swap 'Blinkgeber
        pb.Invalidate() 'Zeichnung anfordern
    End Sub
 
 
    Private Sub pb_Paint(sender As Object, _
        e As System.Windows.Forms.PaintEventArgs) Handles pb.Paint
 
        Dim vl() As String, x%, y%
 
        'Nicht-selektierte Kreise zeichnen (grau)
        Using br As New SolidBrush(Color.Gray)
            For i As Integer = 0 To lbo.Items.Count - 1
                If Not i = lbo.SelectedIndex Then
                    vl = lbo.Items(i).ToString.Split(","c)
                    x = CInt(vl(0)) : y = CInt(vl(1))
                    e.Graphics.FillEllipse(br, x, y, 20, 20)
                End If
            Next i
        End Using
 
        If lbo.SelectedIndex > -1 Then
            Dim col As Color
            'aktuell benötigte Blinkfarbe
            If swap Then col = Color.Red Else col = Color.White
            Using br As New SolidBrush(col)
                'Selektierten Kreis blinken lassen 
                vl = lbo.Items(lbo.SelectedIndex).ToString.Split(","c)
                x = CInt(vl(0)) : y = CInt(vl(1))
                e.Graphics.FillEllipse(br, x, y, 20, 20)
            End Using
        End If
    End Sub
End Class