Public Class frmDataGridComboboxColumn
 
    Dim dgv As New DataGridView With _
        {.Parent = Me, .Height = 300, .AllowUserToAddRows = False}
    Dim WithEvents dt As New DataTable
    Dim WithEvents bs As New BindingSource
 
    Dim WithEvents btnNew As New Button With _
    {.Parent = Me, .Top = dgv.Height + 10, .Text = "New"}
 
    Dim WithEvents btnList As New Button With _
        {.Parent = Me, .Top = btnNew.top, .Left = btnNew.width + 10, .Text = _
        "List"}
 
 
    Private Sub frmDataGridComboboxColumn_Load(sender As System.Object, _
                                        e As System.EventArgs) Handles _
                                        MyBase.Load
 
        Me.Size = New Size(300, 400)
 
        Dim ComboBoxSpalte As New DataGridViewComboBoxColumn
 
        With ComboBoxSpalte
            .HeaderText = "Niederlassung"
            .Name = "Niederlassung"
            .Items.AddRange( _
              New String() {"Berlin", "Köln", "München"})
        End With
 
        dgv.Columns.Add(ComboBoxSpalte)
 
        ' Zuordnung Control-Spalte -> Quell-Spalte
        dgv.Columns(0).DataPropertyName = "Stadt"
 
        'Testdaten
        dt.Columns.Add("Stadt")
 
        dt.Rows.Add("Köln")
        dt.Rows.Add("München")
 
        'Datenbindung
        bs.DataSource = dt
        dgv.DataSource = bs
 
    End Sub
 
 
    Private Sub btnNew_Click(sender As Object, _
            e As System.EventArgs) Handles btnNew.Click
 
        dt.Rows.Add("Berlin") 'neue Quell-Zeile mit Defaultwert
        bs.Position = bs.Count - 1
    End Sub
 
 
    Private Sub btnList_Click(sender As Object, _
        e As System.EventArgs) Handles btnList.Click
 
        'Spalteninhalt auflisten  
        For i As Integer = 0 To dt.Rows.Count - 1
            Dim vl As String = dt.Rows(i)(0).ToString
            If vl = "" Then vl = "null"
            Console.WriteLine(i.ToString & "/" & vl)
        Next i
    End Sub
End Class