Public Class frmThreadFiller
 
    Dim bs As New BindingSource, dt As New DataTable
 
    Dim WithEvents dgv As New DataGridView With _
        {.Parent = Me, .Size = New Size(300, 300), .DataSource = bs}
 
    Dim WithEvents btn As New Button With _
        {.Parent = Me, .Top = 310, .Width = 150, .Text = "Fill"}
 
 
    Private Sub frmThreadFiller_Load(sender As System.Object, _
                            e As System.EventArgs) Handles MyBase.Load
        Me.Size = New Size(400, 400)
    End Sub
 
 
    Private Sub btn_Click(sender As Object, _
                 e As System.EventArgs) Handles btn.Click
 
        'Füllen vorbereiten
        btn.Enabled = False
        bs.DataSource = Nothing
 
        'Füllen der Table in einem eigenen Thread
        Dim th As New Threading.Thread _
            (New Threading.ThreadStart(AddressOf fill))
        th.Start()
 
    End Sub
 
 
    Public Sub fill()
 
        dt.Rows.Clear()
        dt.Columns.Clear()
        For i As Integer = 0 To 6
            dt.Columns.Add("SP_" & (i + 1).ToString, GetType(String))
        Next i
 
        Dim arr(dt.Columns.Count - 1) As String
 
        For i As Integer = 1 To 1000
            Dim row As DataRow = dt.NewRow
            For c As Integer = 0 To 6
                arr(c) = "Zeile " & i.ToString & "  Spalte " & c.ToString
            Next c
            row.ItemArray = arr
            dt.Rows.Add(row)
        Next i
 
        If Me.InvokeRequired Then
            Me.Invoke(New MethodInvoker(AddressOf Filled))
        Else
            Filled()
        End If
    End Sub
 
 
    Private Sub Filled()
        'Datenbindung nach dem Füllen erstellen
        bs.DataSource = dt
        btn.Enabled = True
    End Sub
 
 
    Private Sub dgv_CellPainting(sender As Object, _
                e As System.Windows.Forms.DataGridViewCellPaintingEventArgs) _
            Handles dgv.CellPainting
 
        Dim c As Color
        Select e.RowIndex
            Case Is < 100 : c = Color.White
            Case Is < 200 : c = Color.LightGray
            Case Is < 300 : c = Color.Yellow
            Case Else : c = Color.LightBlue
        End Select
        e.CellStyle.BackColor = c
    End Sub
End Class