Public Class FrmAnimation
 
    Dim WithEvents Pbox As New PictureBox With
        {.Parent = Me, .SizeMode = PictureBoxSizeMode.Zoom, _
         .Dock = DockStyle.Fill}
 
    Dim bmpBackground As New Bitmap(400, 400, _
      Imaging.PixelFormat.Format24bppRgb)
    Dim bmpAnimation As New Bitmap(bmpBackground.Width, bmpBackground.Height)
 
    Dim bmpForeGround1 As New Bitmap(20, 20, Imaging.PixelFormat.Format24bppRgb)
    Dim bmpForeGround2 As New Bitmap(10, 10, Imaging.PixelFormat.Format24bppRgb)
 
 
    Dim WithEvents TimAnimation As New Timer With _
        {.Interval = 40, .Enabled = True}
 
    Dim Posx1, Posy1, Posx2, Posy2 As Integer
 
 
 
    Private Sub FrmAnimation_Load(sender As Object, _
        e As EventArgs) Handles MyBase.Load
 
        Me.DoubleBuffered = True
 
        Using gr As Graphics = Graphics.FromImage(bmpBackground)
            gr.Clear(Color.Yellow)
        End Using
        Using gr As Graphics = Graphics.FromImage(bmpForeGround1)
            gr.Clear(Color.Blue)
        End Using
        Using gr As Graphics = Graphics.FromImage(bmpForeGround2)
            gr.Clear(Color.Red)
        End Using
 
        Pbox.Image = bmpAnimation
    End Sub
 
 
    Private Sub TimAnimation_Tick(sender As Object, _
        e As EventArgs) Handles TimAnimation.Tick
 
        Static vz1 As Integer = 1
        Posx1 = Posx1 + vz1 * 10 : Posy1 = Posy1 + vz1 * 5
 
        Static vz2 As Integer = 1
        Posx2 = Posx2 + vz2 * 5 : Posy2 = Posy2 + vz2 * 10
 
        If Posx1 > bmpBackground.Width - bmpForeGround1.Width _
           Or Posx1 < 0 _
           Or Posy1 > bmpBackground.Height - bmpForeGround1.Height _
           Or Posy1 < 0 Then _
           vz1 *= -1
 
        If Posx2 > bmpBackground.Width - bmpForeGround2.Width _
           Or Posx2 < 0 _
           Or Posy2 > bmpBackground.Height - bmpForeGround2.Height _
           Or Posy2 < 0 Then _
           vz2 *= -1
 
        Using gr As Graphics = Graphics.FromImage(bmpAnimation)
            gr.DrawImage(bmpBackground, 0, 0)
            gr.DrawImage(bmpForeGround1, Posx1, Posy1)
            gr.DrawImage(bmpForeGround2, Posx2, Posy2)
        End Using
 
        Pbox.Invalidate()
    End Sub
End Class