Public Class frmMonthCalender
 
 
    Dim WithEvents mc As New MonthCalendar With
        {.Parent = Me, .Size = New Drawing.Size(200, 200)}
 
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
    Dim dgv As New DataGridView With
        {.Parent = Me, .DataSource = bs, .Top = 220}
 
    Dim WithEvents btnClear As New Button With
        {.Parent = Me, .Left = 220, .Text = "All"}
 
    Dim rndm As New Random(1234)
 
 
    Private Sub frmMonthCalender_Load(sender As Object, _
        e As EventArgs) Handles MyBase.Load
 
        dt.Columns.Add("ID", GetType(Integer))
        dt.Columns.Add("DATE", GetType(DateTime))
 
        For i As Integer = 0 To 1000
            dt.Rows.Add(i, GetRandomDate)
        Next i
 
        bs.DataSource = dt
 
        With mc.DataBindings
            .Add("SelectionStart", bs, "Date", True)
            .Add("SelectionEnd", bs, "Date", True)
        End With
 
        With dt.AsEnumerable
            mc.MinDate = _
              .Min(Of DateTime)(Function(row) row.Field(Of Date)("Date"))
            mc.MaxDate = _
              .Max(Of DateTime)(Function(row) row.Field(Of Date)("Date"))
        End With
 
    End Sub
 
 
    Private Sub mc_DateSelected(sender As Object,
                    e As DateRangeEventArgs) Handles mc.DateSelected
 
        bs.Filter =
            "Date >= " & GetBindingsourceDate(e.Start) &
            " AND Date <= " & GetBindingsourceDate(e.End)
    End Sub
 
 
    Private Sub btnClear_Click(sender As Object, _
        e As EventArgs) Handles btnClear.Click
        bs.RemoveFilter()
    End Sub
 
 
    Private Function GetRandomDate() As Date
        Dim start As Date = New Date(2017, 1, 1)
        Return start.AddDays(rndm.Next(0, 400))
    End Function
 
 
    Private Function GetBindingsourceDate(dat As Date) As String
        Return "#" & dat.Month.ToString & "/" &
            dat.Day.ToString & "/" &
            dat.Year.ToString & "#"
    End Function
End Class