Public Class Form1
    Private mpos As Point
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
        Dim rnd As New Random
        For i As Int32 = 1 To 10
            Dim Pb As New PictureBox
            Pb.Name = "Pb" & i.ToString
            Pb.Image = SystemIcons.Error.ToBitmap
            Pb.Cursor = Cursors.Hand
            Pb.SetBounds(rnd.Next(8) * 32, rnd.Next(8) * 32, 32, 32)
            AddHandler Pb.MouseDown, AddressOf Pb_MouseDown
            AddHandler Pb.MouseMove, AddressOf Pb_MouseMove
            AddHandler Pb.MouseUp, AddressOf Pb_MouseUp
            Me.Controls.Add(Pb)
        Next
    End Sub
    Private Sub Pb_MouseUp(ByVal Sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs)
        Dim p As Control = DirectCast(Sender, Control)
        p.Left = 32 * ((16 + p.Left) \ 32)
        p.Top = 32 * ((16 + p.Top) \ 32)
        Windows.Forms.Cursor.Clip = Nothing
    End Sub
    Private Sub Pb_MouseDown(ByVal Sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs)
        Windows.Forms.Cursor.Clip = RectangleToScreen(Me.ClientRectangle)
        mpos = e.Location
        Me.Text = DirectCast(Sender, Control).Name
    End Sub
    Private Sub Pb_MouseMove(ByVal Sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs)
        If e.Button = Windows.Forms.MouseButtons.Left Then
            Dim c As Control = DirectCast(Sender, Control)
            c.Location = New Point(c.Left + e.X - mpos.X, c.Top + e.Y - mpos.Y)
            c.BringToFront()
        End If
    End Sub
 
    Private Sub Form1_Paint(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.PaintEventArgs) Handles Me.Paint
        e.Graphics.SmoothingMode = Drawing2D.SmoothingMode.AntiAlias
        For y As Int32 = 0 To Me.Height Step 32
            For x As Int32 = 0 To Me.Width Step 32
                e.Graphics.DrawEllipse(Pens.Silver, x, y, 32, 32)
            Next
        Next
    End Sub
End Class