Meinst Du so eine Hierarchie:
Public Class frmParentChild
Dim ds As New DataSet
Dim dtKunde As New DataTable
Dim bsKunde As New BindingSource
Dim dgvKunde As New DataGridView With _
{.Parent = Me, .Width = 200}
Dim dtKFZ As New DataTable
Dim bsKFZ As New BindingSource
Dim dgvKFZ As New DataGridView _
With {.Parent = Me, .Left = 205, .Width = 200}
Dim dtVorgang As New DataTable
Dim bsVorgang As New BindingSource
Dim dgvVorgang As New DataGridView With _
{.Parent = Me, .Left = 410, .Width = 200}
Private Sub Form1_Load(sender As System.Object, _
e As System.EventArgs) Handles MyBase.Load
Me.Width = 630
With dtKunde
.TableName = "Kunde"
.Columns.Add("ID", GetType(Integer))
.Columns.Add("Name", GetType(String))
.Rows.Add(1, "Hans Wurst")
.Rows.Add(2, "Ferdinand Crasher")
.PrimaryKey = {dtKunde.Columns("ID")}
End With
With dtKFZ
.TableName = "KFZ"
.Columns.Add("ID", GetType(Integer))
.Columns.Add("KundeID", GetType(Integer))
.Columns.Add("Marke", GetType(String))
.Rows.Add(1, 1, "Daihatsu")
.Rows.Add(2, 1, "KIA")
.Rows.Add(3, 1, "Honda")
.Rows.Add(4, 2, "Dacia")
.Rows.Add(5, 2, "KIA")
.PrimaryKey = {dtKFZ.Columns("ID")}
End With
With dtVorgang
.TableName = "Vorgang"
.Columns.Add("ID", GetType(Integer))
.Columns.Add("KFZID", GetType(Integer))
.Columns.Add("Typ", GetType(String))
.Rows.Add(1, 1, "Verschrotten")
.Rows.Add(2, 1, "Zerlegen")
.Rows.Add(3, 1, "Entfernen")
.Rows.Add(4, 2, "Tunen")
.Rows.Add(5, 2, "Bestellen")
.Rows.Add(6, 2, "Kunden vertrösten")
.Rows.Add(7, 3, "Ablehnen")
.Rows.Add(8, 4, "Terminieren")
.Rows.Add(9, 4, "Zerlegen")
.Rows.Add(10, 5, "Parken")
.PrimaryKey = {dtVorgang.Columns("ID")}
End With
ds.BeginInit()
ds.Tables.Add(dtKunde)
ds.Tables.Add(dtKFZ)
ds.Tables.Add(dtVorgang)
Dim drKundeKFZ As New DataRelation _
("KundeKFZ", "Kunde", "KFZ", New String() {"ID"}, New String() _
{"KundeID"}, False)
Dim drKFZVorgang As New DataRelation _
("KFZVorgang", "KFZ", "Vorgang", {"ID"}, {"KFZID"}, False)
ds.Relations.AddRange(New DataRelation() {drKundeKFZ, drKFZVorgang})
ds.EndInit()
bsKunde.DataMember = "Kunde"
bsKunde.DataSource = ds
dgvKunde.DataSource = bsKunde
bsKFZ.DataMember = "KundeKFZ"
bsKFZ.DataSource = bsKunde
dgvKFZ.DataSource = bsKFZ
bsVorgang.DataMember = "KFZVorgang"
bsVorgang.DataSource = bsKFZ
dgvVorgang.DataSource = bsVorgang
End Sub
End Class
Beitrag wurde zuletzt am 26.02.14 um 17:50:54 editiert. |