Public Class FlatButtonWithFocusRectangle
    Inherits Button
 
    Public Property FocusBorderColor As Color = Color.Red
    Public Property MouseHooverBorderColor As Color = Color.Green
    Public Property BorderWidth As Integer = 2
 
 
    Protected Overrides Sub OnPaint _
       (pevent As System.Windows.Forms.PaintEventArgs)
 
        MyBase.OnPaint(pevent)
 
        Dim mp As Point = Me.PointToClient(MousePosition)
 
 
        With pevent.Graphics
 
            Using br As New SolidBrush(Me.BackColor)
                .FillRectangle(br, pevent.ClipRectangle)
            End Using
 
            Dim ar As SizeF = .MeasureString _
            (Me.Text, Me.Font, pevent.ClipRectangle.Size, _
            StringFormat.GenericDefault)
 
            Using br As New SolidBrush(Me.ForeColor)
                .DrawString(Me.Text, Me.Font, br, _
                New PointF((pevent.ClipRectangle.Width - ar.Width) / 2, _
                           (pevent.ClipRectangle.Height - ar.Height) / 2))
            End Using
 
            Dim bc As Color = SystemColors.ControlDarkDark
            If .ClipBounds.Contains(mp) Then
                bc = MouseHooverBorderColor
            ElseIf Me.Focused Then
                bc = FocusBorderColor
            End If
            Using pn As New Pen(bc, BorderWidth)
                .DrawRectangle(pn, pevent.ClipRectangle)
            End Using
        End With
    End Sub
End Class