Public Class frmGridColor
 
    Dim WithEvents dgv As New DataGridView With _
        {.Parent = Me, .Dock = DockStyle.Fill}
 
    Dim dt As New DataTable
 
 
 
    Private Sub frmGridColor_Load(sender As System.Object, _
          e As System.EventArgs) Handles MyBase.Load
 
        'Testdaten
        dt.Columns.Add("A") : dt.Columns.Add("B") : dt.Columns.Add("C")
 
        For i As Integer = 1 To 10
            dt.Rows.Add({i, i * 100, i * 1000})
        Next i
 
        'Datenbindung
        dgv.DataSource = dt
 
        dgv.SelectionMode = DataGridViewSelectionMode.FullRowSelect
        dgv.MultiSelect = False
        dgv.Rows(0).Selected = True
 
    End Sub
 
 
 
    Private Sub dgv_CellPainting(sender As Object, _
        e As System.Windows.Forms.DataGridViewCellPaintingEventArgs) _
        Handles dgv.CellPainting
 
        If e.RowIndex < 0 Or e.ColumnIndex < 0 Then Exit Sub
 
        Dim c As DataGridViewCell = dgv.Rows(e.RowIndex).Cells(e.ColumnIndex)
 
        If Not ReferenceEquals(c, dgv.CurrentCell) AndAlso _
            c.RowIndex = dgv.CurrentCell.RowIndex Then
 
            'Zellen in aktueller Zeile ausser der aktuellen Zelle kolorieren
            Using brback As New SolidBrush(Color.DarkGreen), _
                 brfore As New SolidBrush(Color.White)
                e.Graphics.FillRectangle(brback, e.CellBounds)
                e.Graphics.DrawString(c.Value.ToString, dgv.Font, brfore, _
                New PointF(e.CellBounds.X + 3, e.CellBounds.Y + 3))
            End Using
            e.Handled = True
        End If
 
    End Sub
End Class