'Variable für Controls auf Form1
Dim WithEvents tbo As VB.TextBox
Dim WithEvents btn As VB.CommandButton
 
 
'Variable für weitere Formularinstanz
Private subform As New Form1
Public IsSubForm As Boolean 'Kennung für untergeordnete Form-Instanz
 
 
Private Sub btn_Click()
   'Subform erstellen/anzeigen
   subform.Show
 
   'Übergabe des Inhalts der Texteigenschaft
   subform.TBO_Text = Me.TBO_Text
End Sub
 
 
Public Sub InitForm()
   'Instanzen der Controls erstellen und einrichten
   Set tbo = Me.Controls.Add("VB.TextBox", "tbo1")
   tbo.Visible = True
   Set btn = Me.Controls.Add("VB.CommandButton", "btn1")
   btn.Top = 600: btn.Caption = "SubForm"
   btn.Visible = True
End Sub
 
 
Private Sub Form_Load()
     InitForm
     subform.IsSubForm = True 'Kennung unterg. Instanz
End Sub
 
 
 
'Eigenschaft für Setzen und Abfragen eines Textes
Public Property Let TBO_Text(ByVal str As String)
    If Not tbo Is Nothing Then
       tbo.Text = str
    End If
End Property
 
Public Property Get TBO_Text() As String
    If Not tbo Is Nothing Then
       TBO_Text = tbo.Text
    End If
End Property
 
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  'Benutzer-Entladung untergeordneter Formulare verhindern
  If UnloadMode = vbFormControlMenu Then
     Cancel = IsSubForm
     If Cancel Then Me.Hide
  End If
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    'Untergeordnete Formular-Instanzen schließen
    If Not subform Is Nothing Then Unload subform
End Sub
 
 
Public Sub tbo_change()
   'Weitergabe des aktuellen Textes an unterg. Form
   subform.TBO_Text = Me.TBO_Text
End Sub