Option Explicit
 
Private Const DT_TOP = &H8      ' Text an den oberen Rand
Private Const DT_MITTLE = &H10  ' Text vertikal zentrieren
Private Const DT_BOTTOM = &H20  ' Text an den unteren Rand
Private Const DT_LEFT = &H1     ' Text nach links ausrichten
Private Const DT_CENTER = &H2   ' Text horizontal ausrichten
Private Const DT_RIGHT = &H4    ' Text nach rechts ausrichten
 
 
Private Enum DTTEXTALIGNMENT
  dtTopLeft = DT_TOP + DT_LEFT
  dtTopCenter = DT_TOP + DT_CENTER
  dtTopRight = DT_TOP + DT_RIGHT
  dtMittleLeft = DT_MITTLE + DT_LEFT
  dtMittleCenter = DT_MITTLE + DT_CENTER
  dtMittleRight = DT_MITTLE + DT_RIGHT
  dtBottomLeft = DT_BOTTOM + DT_LEFT
  dtBottomCenter = DT_BOTTOM + DT_CENTER
  dtBottomRight = DT_BOTTOM + DT_RIGHT
End Enum
 
Private Sub Form_Load()
  DrawText Picture1, "Test-Text", dtTopCenter
End Sub
 
Private Sub DrawText(picBox As PictureBox, ByVal Text As String, _
  Optional ByVal TextAlignment As DTTEXTALIGNMENT = dtMittleCenter)
 
  Dim X As Single, Y As Single
 
  With picBox
 
    ' stellt sicher, das der Text durch andere Fenster nicht "weggewischt" wird
    .AutoRedraw = True
 
    ' stellt sicher, das Text kein Focus bekommt
    .Enabled = False
 
    ' löscht den Hintergrund der PicturBox
    .Cls
 
    ' WICHTIG! übernimmt die Font-Einstellung der Form
    ' die beiden weiter unten verwendeten VB-Funktionen
    ' "TextWidth" und "TextHeight" berechnen nämlich die
    ' Textgröße in Bezug auf die Form-Schrift
    .Font.Size = Me.Font.Size
 
    ' Text horizontal ausrichten
    If (TextAlignment And DT_LEFT) <> 0 Then X = 0
    If (TextAlignment And DT_CENTER) <> 0 Then X = (.ScaleWidth - TextWidth( _
      Text)) \ 2
    If (TextAlignment And DT_RIGHT) <> 0 Then X = .ScaleWidth - TextWidth(Text)
 
    ' Text vertikal ausrichten
    If (TextAlignment And DT_TOP) <> 0 Then Y = 0
    If (TextAlignment And DT_MITTLE) <> 0 Then Y = (.ScaleHeight - _
      TextHeight(Text)) \ 2
    If (TextAlignment And DT_BOTTOM) <> 0 Then Y = .ScaleHeight - TextHeight(Text)
 
    ' Ausgabe-Position setzen
    .CurrentX = X
    .CurrentY = Y
 
  End With
 
  ' Text ausgeben
  picBox.Print Text
 
End Sub

Viel Spass,
R@lf