Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As _
  Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal _
hObject As Long) As Long
Private Declare Function StretchBlt Lib "gdi32.dll" (ByVal hdc As Long, ByVal X _
As Long, ByVal Y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal _
hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal nSrcWidth As _
Long, ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
 
Private Const HimetricPixel As Single = 26.46
 
Public Sub DrawPicture(ByVal hDC As Long, oPicture As StdPicture, ByVal X1 As _
  Integer, ByVal Y1 As Integer, Optional ByVal Width1 As Integer = -1, Optional _
  ByVal Height1 As Integer = -1, Optional ByVal X2 As Integer = -1, Optional _
  ByVal Y2 As Integer = -1, Optional ByVal Width2 As Integer = -1, Optional _
  ByVal Height2 As Integer = -1)
Dim lPicture As Long
Dim lPicOld As Long
 
lPicture = CreateCompatibleDC(hDC)
lPicOld = SelectObject(lPicture, oPicture.Handle)
 
If Width2 = -1 Then Width2 = oPicture.Width / HimetricPixel
If Height2 = -1 Then Height2 = oPicture.Height / HimetricPixel
If Width1 = -1 Then Width1 = Width2
If Height1 = -1 Then Height1 = Height2
If X2 = -1 Then X2 = 0
If Y2 = -1 Then Y2 = 0
 
Call StretchBlt(hDC, X1, Y1, Width1, Height1, lPicture, X2, Y2, Width2, _
  Height2, vbSrcCopy)
 
Call SelectObject(lPicture, lPicOld)
Call DeleteDC(lPicture)
End Sub