' Controls: 1 Button mit Index = 0
 
Option Explicit
 
' UDT
Private Type CntrlDat
  XPos As Single
  YPos As Single
End Type
 
Private XD!, YD!, TwX!, TwY!
Private Dat1$
 
Private Sub Form_Load()
 
  Dim i&, CInfo As CntrlDat, NewIndex&
 
  Me.ScaleMode = vbPixels
  TwX = Screen.TwipsPerPixelX
  TwY = Screen.TwipsPerPixelY
  Command1(0).Caption = "Neuer Button"
 
  Dat1 = App.Path
  If Right$(Dat1, 1) <> "\" Then Dat1 = Dat1 & "\"
  Dat1 = Dat1 & "Cntr.dat"
  If Dir$(Dat1) <> "" Then
    ' Controls laden
    Open Dat1 For Random As #1 Len = Len(CInfo)
      For i = 1 To LOF(1) \ Len(CInfo)
        Get #1, , CInfo
        NewIndex = Command1.Count
        Load Command1(NewIndex)
        With Command1(NewIndex)
          .Move CInfo.XPos, CInfo.YPos
          .Caption = "Button " & NewIndex
          .ZOrder vbBringToFront
          .Visible = True
        End With
      Next i
    Close #1
  End If
End Sub
 
Private Sub Command1_Click(Index As Integer)
  ' Neues Control anlegen
  Dim NewIndex&
 
  If Index = 0 Then
    NewIndex = Command1.Count
    Load Command1(NewIndex)
    With Command1(NewIndex)
      .Move (Me.ScaleWidth - .Width) \ 2, (Me.ScaleHeight - .Height) \ 2
      .Caption = "Button " & NewIndex
      .ZOrder vbBringToFront
      .Visible = True
    End With
  End If
End Sub
 
Private Sub Command1_MouseDown(Index As Integer, Button As Integer, Shift As _
  Integer, X As Single, Y As Single)
  If Index > 0 Then
    XD = X: YD = Y
    Command1(Index).ZOrder vbBringToFront
  End If
End Sub
 
Private Sub Command1_MouseMove(Index As Integer, Button As Integer, Shift As _
  Integer, X As Single, Y As Single)
  If Button = vbLeftButton And Index > 0 Then
    With Command1(Index)
      .Move .Left + (X - XD) / TwX, .Top + (Y - YD) / TwY
    End With
  End If
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
  Dim i&, CInfo As CntrlDat
 
  If Command1.UBound > 0 And Dat1 <> "" Then
    ' Controls speichern
    Open Dat1 For Random As #1 Len = Len(CInfo)
      For i = 1 To Command1.UBound
        With Command1(i)
          CInfo.XPos = .Left
          CInfo.YPos = .Top
        End With
        Put #1, i, CInfo
      Next i
    Close #1
  End If
End Sub

Gruss,

Zardoz