Public Class frmComboBinding
 
    Dim dt As New DataTable, bs As BindingSource
 
    Dim dgv As New DataGridView With {.Parent = Me, .Top = 50}
    Dim WithEvents cbo As New ComboBox With {.Parent = Me}
 
 
    Private Sub frmComboBinding_Load(sender As System.Object, _
                         e As System.EventArgs) Handles MyBase.Load
 
        'Testspalten
        dt.Columns.Add("ID", GetType(Integer))
        dt.Columns.Add("Date", GetType(Date))
 
        'Testdaten
        Dim year As Integer = 2000, id As Integer = 0
        For i As Integer = 1 To 10
            year += 1 : id += 1
            dt.Rows.Add(id, New Date(year, i + 1, 15))
            id += 1
            dt.Rows.Add(id, New Date(year, i, 25))
        Next i
 
        'Datenbindung Quelle
        bs = New BindingSource With {.DataSource = dt}
 
        'Sortierspalte und Richtung festlegen
        bs.Sort = "Date ASC"
 
        dgv.DataSource = bs
 
        'Ermittlung der Jahreszahlen als Liste (LINQ)
        Dim dates As List(Of Integer) = _
            (From rw As DataRow In dt.AsEnumerable _
             Let Vl = CInt(rw.Field(Of Date)("Date").ToString("yyyy"))
             Select Vl Distinct).ToList
 
        'Liste an Combobox binden
        cbo.DataSource = dates
 
    End Sub
 
 
    Private Sub cbo_SelectedIndexChanged(sender As Object, _
        e As System.EventArgs) Handles cbo.SelectedIndexChanged
 
        If cbo.SelectedIndex = -1 Then
            bs.Filter = ""
        Else
            'Filter setzen: Datumswerte im Standardformat angeben
            Dim year As String = cbo.SelectedItem.ToString
            bs.Filter = _
             "Date >= #1/1/" & year & "# AND Date <= #12/31/" & year & "#"
        End If
    End Sub
End Class