Dim drawBm As Boolean
    Dim pb As PictureBox
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles Button1.Click
        drawBm = Not drawBm
        If drawBm Then
            If pb Is Nothing Then
                pb = New PictureBox
                Dim bm As New Bitmap(Me.Width, Me.Height)
                Me.DrawToBitmap(bm, New Rectangle(0, 0, Me.Width, Me.Height))
                MakeImageGrayscale(bm)
                pb.Left = (Me.ClientSize.Width - Me.Width) / 2
                pb.Top = (Me.ClientSize.Height - Me.Height) - pb.Left
                pb.Width = Me.Width
                pb.Height = Me.Height
                pb.BackgroundImage = bm
                AddHandler pb.Click, AddressOf PBClick
            End If
            Me.Controls.Add(pb)
            pb.BringToFront()
        Else
            If pb Is Nothing Then Return
            pb.BackgroundImage.Dispose()
            pb.Dispose()
            pb = Nothing
        End If
    End Sub
 
    Private Sub PBClick(ByVal sender As System.Object, ByVal e As _
      System.EventArgs)
        Dim mp As Point = Me.PointToClient(MousePosition)
        If Button1.Bounds.Contains(mp) Then
            Button1.PerformClick()
        End If
    End Sub
 
    Public Shared Sub MakeImageGrayscale(ByVal bmp As Bitmap)
        Dim cm As New ColorMatrix(New Single()() _
            {New Single() {0.299, 0.299, 0.299, 0, 0}, _
            New Single() {0.587, 0.587, 0.587, 0, 0}, _
            New Single() {0.114, 0.114, 0.114, 0, 0}, _
            New Single() {0, 0, 0, 1, 0}, _
            New Single() {0, 0, 0, 0, 1}})
 
        Using iatt As New ImageAttributes, _
            gr As Graphics = Graphics.FromImage(bmp)
            iatt.SetColorMatrix(cm)
            gr.DrawImage(bmp, New Rectangle(0, 0, bmp.Width, bmp.Height), _
              0, 0, bmp.Width, bmp.Height, GraphicsUnit.Pixel, iatt)
        End Using
    End Sub

________
Alle Angaben ohne Gewähr. Keine Haftung für Vorschläge, Tipps oder sonstige Hilfe, falls es schiefgeht, nur Zeit verschwendet oder man sonst nicht zufrieden ist