Option Explicit
 
Private Type POINTAPI
  x As Long
  y As Long
End Type
 
Private Declare Function PtInRegion Lib "gdi32" (ByVal hRgn As Long, ByVal x As _
  Long, ByVal y As Long) As Long
Private Declare Function CreatePolygonRgn Lib "gdi32" (lpPoint As POINTAPI, _
ByVal nCount As Long, ByVal nPolyFillMode As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As _
Long
Private Declare Function Polygon& Lib "gdi32" (ByVal hdc&, lpPoint As POINTAPI, _
ByVal nCount&)
 
Private Const ALTERNATE& = 1
 
Private Rgn1&
 
Private Sub Form_Load()
  Dim i%, PtLst(2) As POINTAPI
 
  ' Eckpunkte des Dreiecks eintragen
  For i = 0 To 2
    PtLst(i).x = Choose(i + 1, 50, 150, 90)
    PtLst(i).y = Choose(i + 1, 50, 70, 150)
  Next i
 
  Rgn1 = CreatePolygonRgn(PtLst(0), 3, ALTERNATE)
  With Me
    .ScaleMode = vbPixels
    .AutoRedraw = True
    .FillColor = vbYellow
    .ForeColor = vbBlack
    .FillStyle = vbFSSolid
    Call Polygon(.hdc, PtLst(0), 3)
  End With
End Sub
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, x As Single, y _
  As Single)
  If PtInRegion(Rgn1, x, y) <> 0 Then
    Me.Caption = Space$(5) & "Punkt im Dreieck"
  Else
    Me.Caption = Space$(5) & "Punkt außerhalb"
  End If
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
  Call DeleteObject(Rgn1)
End Sub

Gruss,

Zardoz