'Benötigt werden je 1 mal: PictureBox, Frame, Timer, Image und
'CommandButton bei dem die Index-Eigenschaft auf 0 gesetzt ist.
Private XR%, YR%, TwX%, TwY%
 
Private Sub Command1_MouseDown(Index As Integer, Button As Integer, Shift As _
  Integer, X As Single, Y As Single)
  Select Case Index
    Case 0: XR = 1
    Case 1: XR = -1
    Case 2: YR = 1
    Case 3: YR = -1
  End Select
End Sub
 
Private Sub Command1_MouseUp(Index As Integer, Button As Integer, Shift As _
  Integer, X As Single, Y As Single)
  XR = 0
  YR = 0
End Sub
 
Private Sub Form_Activate()
  Dim i%, Breite%, Höhe%
  Breite = 1000
  Höhe = 1000
  Me.BackColor = vbBlack
  Me.ScaleMode = vbPixels
  Me.WindowState = vbMaximized
  Randomize
  TwX = Screen.TwipsPerPixelX
  TwY = Screen.TwipsPerPixelY
  With Frame1
  .Move 10, 10, 300, 300
  .Caption = ""
  .BorderStyle = 0
  .BackColor = RGB(60, 30, 0)
  End With
  With Picture1
  .Visible = False
  .BorderStyle = 0
  .AutoRedraw = True
  .BackColor = Frame1.BackColor
  .ScaleMode = vbPixels
  .FillStyle = 0
  .Move 0, 0, Breite, Höhe
  .Cls
  For i = 1 To 1000
    .FillColor = RGB(0, Rnd * 255, 0)
    Picture1.Circle (Rnd * Breite, Rnd * Höhe), 10
  Next i
  Set Image1.Container = Frame1
  Set Image1.Picture = .Image
  .Cls
  .AutoRedraw = False
  End With
  XR = 0
  YR = 0
  For i = 0 To 3
    If i > 0 Then Load Command1(i)
    With Command1(i)
    .Font = "Marlett"
    .FontSize = 20
    .Caption = 3 + i
    .Move 320, 20 + i * 40, 35, 35
    .Visible = True
    End With
  Next i
  Timer1.Interval = 100
End Sub
Private Sub Timer1_Timer()
  Dim X%, Y%
  With Image1
  X = .Left + TwX * XR * 10
  Y = .Top + TwY * YR * 10
  If X > 0 Then X = 0
  If Y > 0 Then Y = 0
  If X < Frame1.Width * TwX - .Width Then X = Frame1.Width * TwX - .Width
  If Y < Frame1.Height * TwY - .Height Then Y = Frame1.Height * TwY - .Height
  .Move X, Y
  End With
End Sub