Public Class cTextAppend
 
    ' Verweis auf die Textbox
    Private _TextBox As Windows.Forms.TextBox
 
    ' Speichert den hinzuzufügenden Text.
    Private _NewText As String
 
    'Konstruktor: Verweis auf die Textbox   
    Public Sub New(ByVal TheTextbox As TextBox)
        Me._TextBox = TheTextbox
    End Sub
 
    'Anhängen von Text an die Textbox   
    Public Sub AppendText(ByVal newText As String)
       SyncLock Me
         Me._NewText = newText
         _TextBox.Invoke _
         (New MethodInvoker(AddressOf ThreadSafeAddText))
       End SyncLock
    End Sub
 
    Private Sub ThreadSafeAddText()
        _TextBox.AppendText(_NewText)
    End Sub
 
    'Löschen des Textes in der Textbox
    Public Sub Clear()
       SyncLock Me
         _TextBox.Invoke _
         (New MethodInvoker(AddressOf ThreadSafeClearText))
      End SyncLock
    End Sub
 
    Private Sub ThreadSafeClearText()
        _TextBox.Clear()
    End Sub
End Class

 
Public Class frmThreadDemo
 
    Dim tb As New TextBox _
    With {.Parent = Me, .Top = 10, .Left = 10, _
      .Width = 200, .Height = 200, .Multiline = True}
 
    Dim WithEvents btnStart As New Button _
    With {.Parent = Me, .Top = 10, .Left = 220, .Text = "Start"}
 
    Dim TextBoxAppend As cTextAppend
 
    Private Sub Load(sender As System.Object, _
            e As System.EventArgs) Handles MyBase.Load
        'Instanz des Wrapper zum Füllen der Textbox
        TextBoxAppend = New cTextAppend(tb)
    End Sub
 
    Private Sub Count()
      'Die Methode, die in einem eigenen Thread ausgeführt
      'wird und per Wrapper die Textbox füllt
      Static counter As Long = 0
      If counter >= 300 Then
         counter = 0
         'Methode der Wrapperklasse aufrufen
         TextBoxAppend.Clear()
      End If
 
      For i As Integer = 0 To 100
         counter += 1
         'Methode der Wrapperklasse aufrufen
         TextBoxAppend.AppendText(CStr(counter) & vbCrLf)
      Next i
    End Sub
 
    Private Sub btnStart_Click(sender As Object, _
        e As System.EventArgs) Handles btnStart.Click
        Dim CountThread As New Threading.Thread(AddressOf Count)
        CountThread.Start()
    End Sub
End Class