'Lege ein Frame, eine Picturebox, eine horizontale
'und eine vertikale Bildlaufleiste in die Form
Option Explicit
 
Private TwX As Integer, TwY As Integer
Private Breite As Integer, Höhe As Integer
 
Private Sub Form_Activate()
  Call ZeichneFraktal 'Beispiel
End Sub
 
Private Sub Form_Load()
  Breite = 1200 'Bildbreite der Grafik in Pixeln
  Höhe = 1000 'Bildhöhe in Pixeln
  Me.ScaleMode = vbPixels
  Me.BackColor = RGB(0, 0, 48)
  TwX = Screen.TwipsPerPixelX
  TwY = Screen.TwipsPerPixelY
  With Frame1
  .Caption = ""
  .BorderStyle = 0
  .Move 10, 10, 400, 280 'Position+Größe des Ausschnitts
  .BackColor = vbBlack
  HScroll1.Move .Left, .Top + .Height, .Width
  VScroll1.Move .Left + .Width, .Top, VScroll1.Width, .Height
  HScroll1.Max = Breite - .Width
  VScroll1.Max = Höhe - .Height
  End With
  HScroll1.LargeChange = 10
  VScroll1.LargeChange = 10
  With Picture1
  Set .Container = Frame1
  .BorderStyle = 0
  .TabStop = False
  .ScaleMode = vbPixels
  .AutoRedraw = True
  .BackColor = vbBlack
  .Move 0, 0, Breite * TwX, Höhe * TwY
  .Cls
  End With
End Sub
 
Private Sub HScroll1_Change()
  Call HScroll1_Scroll
End Sub
 
Private Sub HScroll1_Scroll()
  Picture1.Left = -HScroll1.Value * TwX
End Sub
 
Private Sub VScroll1_Change()
  Call VScroll1_Scroll
End Sub
 
Private Sub VScroll1_Scroll()
  Picture1.Top = -VScroll1.Value * TwY
End Sub
 
Private Sub ZeichneFraktal()
  Dim i As Integer, j As Integer
 
  For i = 0 To Höhe - 1
    For j = 0 To Breite - 1
      If i And j Then Picture1.PSet (j, i), IIf(Rnd < 0.5, vbRed, vbYellow)
    Next j
    DoEvents
  Next i
End Sub