Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function GetWindowLong Lib "user32" _
  Alias "GetWindowLongA" ( _
  ByVal hwnd As Long, _
  ByVal nIndex As Long) As Long
 
Private Declare Function SetWindowLong Lib "user32" _
  Alias "SetWindowLongA" ( _
  ByVal hwnd As Long, _
  ByVal nIndex As Long, _
  ByVal dwNewLong As Long) As Long
 
Private Declare Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal hWndInsertAfter As Long, _
  ByVal x As Long, ByVal y As Long, _
  ByVal cx As Long, ByVal cy As Long, _
  ByVal wFlags As Long) As Long
 
Private Const GWL_STYLE = (-16)
Private Const SWP_FRAMECHANGED = &H20
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOACTIVATE = &H10
 
Private Const WS_CAPTION = &HC00000
Private Const WS_BORDER = &H800000

Private Sub Form_ShowCaption(oForm As Form, _
  ByVal bShowCaption As Boolean)
 
  Dim nStyle As Long
  Dim nFlags As Long
 
  With oForm
    ' Form ausblenden
 
    ' aktuellen Style ermitteln
    nStyle = GetWindowLong(.hwnd, GWL_STYLE)
 
    ' Caption anzeigen?
    If bShowCaption Then
      nStyle = nStyle Or WS_CAPTION
    Else
      nStyle = nStyle And Not WS_CAPTION
    End If
 
    ' Neuen Style setzen
    Call SetWindowLong(.hwnd, GWL_STYLE, nStyle)
 
    ' Form einblenden
     nFlags = SWP_NOACTIVATE Or SWP_FRAMECHANGED Or _
       SWP_NOSIZE Or SWP_NOMOVE
    SetWindowPos .hwnd, 0, 0, 0, 0, 0, nFlags
  End With
End Sub

' Titelzeile ausblenden
Form_ShowCaption Me, False
 
' Titelzeile wieder einblenden
Form_ShowCaption Me, True

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de