'Benötigt werden: Frame1, Label1 mit Index = 0 , Label2
 
Option Explicit
 
Private XD!
 
Private Sub Form_Load()
 
Dim i%
 
Me.WindowState = vbMaximized
Me.ScaleMode = vbTwips
For i = 0 To 99
  If i > 0 Then Load Label1(i)
  With Label1(i)
    Set .Container = Frame1
    .BorderStyle = vbBSSolid
    .Caption = "- " & i & " -"
    .Visible = True
  End With
Next i
 
End Sub
 
Private Sub Form_Activate()
 
Frame1.BorderStyle = vbBSNone
Frame1.BackColor = RGB(200, 200, 255)
Frame1.Move 0, 0, 300 * 15, Me.ScaleHeight
Label2.Caption = "< >"
Label2.Move 300 * 15, 200 * 15, 32 * 15, 32 * 15
Label2.BorderStyle = vbBSSolid
Label2.BackColor = vbYellow
Call Label2_MouseUp(0, 0, 0, 0)
 
End Sub
 
Private Sub Label2_MouseDown(Button As Integer, Shift As Integer, X As Single, _
  Y As Single)
 
XD = X
 
End Sub
 
Private Sub Label2_MouseMove(Button As Integer, Shift As Integer, X As Single, _
  Y As Single)
 
If Button = vbLeftButton Then
  Label2.Left = Label2.Left + X - XD
  Frame1.Width = Label2.Left - Frame1.Left
End If
 
End Sub
 
Private Sub Label2_MouseUp(Button As Integer, Shift As Integer, X As Single, Y _
  As Single)
 
Dim i%, XPos!, YPos!
 
XPos = 0
YPos = 0
 
Frame1.Visible = False
For i = 0 To Label1.UBound
  If XPos + Label1(i).Width > Frame1.Width And XPos > 0 Then
    XPos = 0
    YPos = YPos + Label1(0).Height
  End If
  Label1(i).Move XPos, YPos
  XPos = XPos + Label1(i).Width
Next i
Frame1.Visible = True
 
End Sub

Gruss,

Zardoz