Public Class ParameterInfo
 
    Public Enum ParamType
        [Double]
        Text
        TextArray
        DoubleArray
    End Enum
 
    Public Enum ControlType
        TextBox
        Combobox
        ListBox
        Button
    End Enum
 
 
    Dim _param_name As String
    Public ReadOnly Property Param_Name As String
        Get
            Return _param_name
        End Get
    End Property
 
 
    Dim _param_type As ParamType
    Public ReadOnly Property Param_type As ParamType
        Get
            Return _param_type
        End Get
    End Property
 
 
    Public Property Param_Value As Object 'einer der Parametertypen
 
 
    Dim _control_type As ControlType
    Dim _control_location As Point
    Dim _control_size As Size
 
    'Position und Größe des zugeordneten Labels
    'Diese Angaben könnten auch relativ zu den entsprechenden
    'Control-Eigenschaften berechnet werden.
    Dim _label_location As Point
    Dim _label_size As Size
 
 
    ''' <param name="Param_Name">eindeutiger Name des Parameters 
    ''' (=Text im Label, Name des Control)</param>
    ''' <param name="Param_Type">Datentyp des Parameters</param>
    ''' <param name="Param_Value">Wert des Parameters 
    ''' (wird im Control angezeigt)</param>
    ''' <param name="Control_Type">Typ des Control</param>
    ''' <param name="Control_Location">Position des Control auf dem Container 
    ''' (gegeben in CreateControl)</param>
    ''' <param name="Control_Size">Größe des Control (Pixel)</param>
    ''' <param name="Label_Location">Position des Label, 
    ''' das dem Control zugeordnet ist</param>
    Public Sub New _
        (Param_Name As String, Param_Type As ParamType, _
         Param_Value As Object, _
         Control_Type As ControlType, _
         Control_Location As Point, Control_Size As Size, _
         Label_Location As Point, Label_Size As Size)
 
        _param_name = Param_Name
        _param_type = Param_Type
        _Param_Value = Param_Value
 
        _control_type = Control_Type
        _control_location = Control_Location
        _control_size = Control_Size
 
        _label_location = Label_Location
        _label_size = Label_Size
 
    End Sub
 
 
    Public Function CreateControl(ByVal f As Control) As Control
 
        'f ist der Container, in dem die Controls erstellt werden
 
        Dim ctl As Control = Nothing
 
        'Label zum Control erstellen und positionieren
        Dim lbl As New Label With _
            {.Parent = f, _
             .Location = _label_location, .Size = _label_size, _
             .Text = _param_name, .AutoSize = False}
 
        'Control erstellen und aktuellen Value eintragen
        Select Case _control_type
            Case ControlType.Button
                ctl = New Button With _
                   {.Text = GetValue(0).ToString}
            Case ControlType.TextBox
                ctl = New TextBox With _
                   {.Text = GetValue(0).ToString}
            Case ControlType.Combobox
                Dim cbo As New ComboBox
                cbo.Items.AddRange(GetValue())
                ctl = cbo
            Case ControlType.ListBox
                Dim lbo As New ListBox
                lbo.Items.AddRange(GetValue)
                ctl = lbo
        End Select
 
        If ctl IsNot Nothing Then
            'allgemeine Control-Eigenschaften
            With ctl
                .Parent = f
                .Name = _param_name
                .Location = _control_location
                .Size = _control_size
            End With
        End If
        Return ctl
    End Function
 
 
    Private Function GetValue() As Object()
 
        'Cast der Parameter-Value-Typen
        Dim items() As Object = Nothing
        If TypeOf _Param_Value Is Double() Then
            Dim dbl As Double() = CType(_Param_Value, Double())
            ReDim items(dbl.Length - 1)
            For i As Integer = 0 To dbl.Length - 1
                items(i) = dbl(i)
            Next i
        ElseIf TypeOf _Param_Value Is String() Then
            Dim str As String() = CType(_Param_Value, String())
            ReDim items(str.Length - 1)
            For i As Integer = 0 To str.Length - 1
                items(i) = str(i)
            Next i
        Else
            ReDim items(0)
            items(0) = _Param_Value
        End If
        Return items
    End Function
 
End Class

Public Class frmDynCtl
 
    'Liste der Parameter
    Dim pil As New List(Of ParameterInfo)
 
 
    Private Sub frmDynCtl_Load(sender As System.Object, _
                    e As System.EventArgs) Handles MyBase.Load
 
        Dim control_height As Integer = 50
        Dim control_size As New Size(150, 30)
        Dim label_size As New Size(80, 30)
 
        'Parameter_Infos erstellen und auflisten
        pil.Add(New ParameterInfo _
                    ("TBO1_Name", ParameterInfo.ParamType.Text, _
                    "TBO1_Value", _
                    ParameterInfo.ControlType.TextBox, _
                    New Point(100, 20), control_size, _
                    New Point(10, 20), label_size))
 
        pil.Add(New ParameterInfo _
                    ("TBO2_Name", ParameterInfo.ParamType.Double, 5247.15, _
                    ParameterInfo.ControlType.TextBox, _
                    New Point(100, 20 + control_height), control_size, _
                    New Point(10, 20 + control_height), label_size))
 
        pil.Add(New ParameterInfo _
                    ("LBO1_Name", ParameterInfo.ParamType.TextArray, _
                     New String() {"LBO1_Item1", "LBO1_Item2", "LBO1_Item3"}, _
                    ParameterInfo.ControlType.ListBox, _
                    New Point(100, 20 + control_height * 2), control_size, _
                    New Point(10, 20 + control_height * 2), label_size))
 
        pil.Add(New ParameterInfo _
                    ("CBO1_Name", ParameterInfo.ParamType.DoubleArray, _
                     New Double() {10.7, 12.65, 3.561}, _
                    ParameterInfo.ControlType.Combobox, _
                    New Point(100, 20 + control_height * 3), control_size, _
                    New Point(10, 20 + control_height * 3), label_size))
 
        pil.Add(New ParameterInfo _
                    ("BTN1_Name", ParameterInfo.ParamType.Text, "BTN1_Value", _
                    ParameterInfo.ControlType.Button, _
                    New Point(100, 20 + control_height * 4), control_size, _
                    New Point(10, 20 + control_height * 4), label_size))
 
 
        'Das ContainerControl 
        Dim pan As New Panel With _
            {.Parent = Me, .Top = 10, _
             .Width = 300, .Height = control_height * 5, _
             .BackColor = Color.LightGray}
 
        'benötigte Controls für die ParameterInfos erstellen
        'und mit den Eventhandler-Routinen kombinieren
        For Each pi As ParameterInfo In pil
            Dim ctl As Control = pi.CreateControl(pan)
 
            If TypeOf ctl Is ComboBox Then
                Dim cbo As ComboBox = DirectCast(ctl, ComboBox)
                AddHandler cbo.SelectedIndexChanged, _
                           AddressOf Selectedindex_changed
            ElseIf TypeOf ctl Is TextBox Then
                Dim tbo As TextBox = DirectCast(ctl, TextBox)
                AddHandler tbo.TextChanged, AddressOf text_changed
            Else
                AddHandler ctl.Click, AddressOf Ctl_click
            End If
        Next pi
 
    End Sub
 
    Public Sub Ctl_click(ByVal sender As Object, e As EventArgs)
 
        Dim ctl As Control = DirectCast(sender, Control)
        MsgBox(ctl.Name & " wurde gedrückt")
 
    End Sub
 
 
    Public Sub Selectedindex_changed(ByVal sender As Object, e As EventArgs)
 
        Dim cbo As ComboBox = DirectCast(sender, ComboBox)
        MsgBox("Index " & cbo.SelectedIndex.ToString & " wurde ausgewählt")
 
    End Sub
 
    Public Sub text_changed(ByVal sender As Object, e As EventArgs)
 
        Dim tbo As TextBox = DirectCast(sender, TextBox)
        MsgBox("Neuer Text: " & tbo.Text)
 
    End Sub
End Class

   Public Enum ParamType
      [Double]
      Text
      TextArray
      DoubleArray
   End Enum
 
   Public Enum ControlType
      TextBox
      Combobox
      ListBox
      Button
   End Enum