Public Class frmBoolInput
 
    Const Columns As Integer = 20
    Const Rows As Integer = 30
    Const ColumnWidth As Integer = 20 'Pixel
    Const RowHeight As Integer = 10 'Pixel
 
    Dim WithEvents pb As New PictureBox With {.Parent = Me}
    Dim bools(Columns - 1, Rows - 1) As Boolean
 
    Dim truecolor As Color = Color.Red
    Dim falsecolor As Color = Color.White
 
 
    Private Sub frmBoolInput_Load(sender As System.Object, _
                                  e As System.EventArgs) Handles MyBase.Load
 
        pb.Size = New Size(Columns * ColumnWidth, Rows * RowHeight)
        Me.Size = Size.Add(pb.Size, New Size(10, 30))
        Me.FormBorderStyle = _
              Windows.Forms.FormBorderStyle.FixedDialog
    End Sub
 
 
    Private Sub pb_MouseDown(sender As Object, _
        e As System.Windows.Forms.MouseEventArgs) Handles pb.MouseDown
 
        Dim colindex As Integer = e.X \ ColumnWidth
        Dim rowindex As Integer = e.Y \ RowHeight
        bools(colindex, rowindex) = Not bools(colindex, rowindex)
 
        pb.Invalidate()
    End Sub
 
 
    Private Sub pb_Paint(sender As Object, _
        e As System.Windows.Forms.PaintEventArgs) Handles pb.Paint
 
        Dim br As Brush, r As Rectangle
        Using brtrue As New SolidBrush(truecolor), _
            brfalse As New SolidBrush(falsecolor), _
            pFrame As New Pen(Color.Black)
 
            For i As Integer = 0 To Columns - 1
                For k As Integer = 0 To Rows - 1
                    br = If(bools(i, k), brtrue, brfalse)
                    r = New Rectangle _
                        (i * ColumnWidth, k * RowHeight, _
                         ColumnWidth, RowHeight)
                    e.Graphics.FillRectangle(br, r)
                    e.Graphics.DrawRectangle(pFrame, r)
                Next k
            Next i
        End Using
 
    End Sub
End Class