If RichTextBox1.Text.Contains(TextBox1.Text) Then
            RichTextBox1.Find(TextBox1.Text)
            RichTextBox1.SelectionBackColor = Color.Red
        End If

Public Class frmMarker
 
    Dim rtf As New RichTextBox With
        {.Parent = Me, .Height = 400, .Width = 400, .HideSelection = False}
    Dim WithEvents txt As New TextBox With
        {.Parent = Me, .Top = 410, .Width = 400}
 
 
    Private Sub frmMarker_Load(sender As Object, _
        e As EventArgs) Handles MyBase.Load
 
        Me.Width = 420
        Me.Height = 480
 
        Dim sb As New System.Text.StringBuilder(1024)
        For i As Integer = 0 To 99
            sb.Append _
            ("Das ist ein Demonstrations-Satz zum Zwecke der Erstellung eines" & _
            "Textes.")
            sb.Append(vbNewLine)
        Next i
        rtf.Text = sb.ToString
    End Sub
 
 
    Private Sub txt_KeyDown(sender As Object, _
        e As KeyEventArgs) Handles txt.KeyDown
 
        If e.KeyCode = Keys.Return AndAlso _
            Not String.IsNullOrEmpty(txt.Text) Then
 
            Me.Text = MarkFoundTextPassage(txt.Text).ToString & " Fundstellen"
        End If
    End Sub
 
 
    Private Function MarkFoundTextPassage(ByVal mrk As String,
               Optional ByVal CLEARSELECTION As Boolean = True) As Integer
 
        Dim c As Integer = 0
        With rtf
            If CLEARSELECTION Then
                .SelectionStart = 0
                .SelectionLength = .Text.Length
                .SelectionColor = .ForeColor
                .SelectionBackColor = .BackColor
                .SelectionLength = 0
            End If
            Dim pos As Integer = -1
            Do
                pos = .Find(mrk, pos + 1, .Text.Length, RichTextBoxFinds.None)
                If pos < 0 Then
                    Return c
                End If
                .SelectionStart = pos
                .SelectionLength = mrk.Length
                .SelectionColor = Color.White
                .SelectionBackColor = Color.Blue
                c += 1
            Loop While pos >= 0
        End With
        Return c
    End Function
End Class