Dim Gleisplan As New Bitmap(GpX, GpY, PixelFormat.Format32bppArgb)
Dim g As Graphics = Graphics.FromImage(GleisPlan)

    Dim Gpx, GPy As Integer
    Gpx = 24361
    GPy = 5966
 
    Dim Gleisplan As New Bitmap(GpX, GpY, PixelFormat.Format32bppArgb)
 
    Using g As Graphics = Graphics.FromImage(Gleisplan),
            pn As New System.Drawing.Pen(Color.Blue, 4)
        g.Clear(Color.Yellow)
        g.DrawLine(pn, 0, 0, 24000, 5500)
    End Using
    Gleisplan.Save("G:\downloads\gleisplan.png", _
      Drawing.Imaging.ImageFormat.Png)
 
    Gleisplan.Dispose()
    Gleisplan = Nothing

Public Class Form1
 
    Dim pb As New PictureBox With
        {.Parent = Me, .Top = 10, .Left = 10, .Width = 300, .Height = 300,
        .SizeMode = PictureBoxSizeMode.Zoom, .BackColor = Color.White,
        .BorderStyle = BorderStyle.Fixed3D}
 
    Dim WithEvents btnCreateBitmap As New Button With
        {.Parent = Me, .Top = 320, .Left = 10, .Width = 300, .Text = "Create"}
    Dim WithEvents btnKillBitmap As New Button With
        {.Parent = Me, .Top = 360, .Left = 10, .Width = 300, .Text = "Kill"}
    Dim WithEvents btnSaveBitmap As New Button With
        {.Parent = Me, .Top = 400, .Left = 10, .Width = 300, .Text = "Save"}
 
    Dim Gleisplan As Bitmap
    Dim rndm As New Random(Now.Millisecond)
 
 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
 
        Me.MinimumSize = New Size(350, 500)
    End Sub
 
 
    Private Sub CreateBitmap()
 
        DeleteBitmap() 'Freigabe sicher stellen
 
        Dim Gpx, GPy, x1, y1, x2, y2 As Integer
        Gpx = 24361
        GPy = 5966
 
        Gleisplan = New Bitmap(Gpx, GPy,
             Imaging.PixelFormat.Format32bppArgb)
 
        pb.Image = Gleisplan
 
        Using g As Graphics = Graphics.FromImage(Gleisplan),
                pn As New System.Drawing.Pen(Color.Blue, 8)
            g.Clear(Color.Yellow)
            For i As Integer = 0 To 10
                x2 = x1
                y2 = y1
                x1 = CInt(rndm.NextDouble() * Gpx)
                y1 = CInt(rndm.NextDouble() * GPy)
                g.DrawLine(pn, x1, y1, x2, y2)
            Next i
        End Using
 
    End Sub
 
 
    Private Sub SaveBitmap()
        If Gleisplan Is Nothing Then Exit Sub
 
        Dim filepath As String = "G:\downloads\gleisplan.png"
        IO.File.Delete(filepath)
        Gleisplan.Save(filepath, Drawing.Imaging.ImageFormat.Png)
    End Sub
 
 
    Private Sub DeleteBitmap()
 
        'Referenz in der Picturebox aufheben
        pb.Image = Nothing
 
        If Gleisplan IsNot Nothing Then
            'Windows-Resourcen (Handles etc.) der Bitmap entfernen
            Gleisplan.Dispose
            'Letzte Referenz auf die Bitmap aufheben
            '(Löschen der Net-Klasse anfordern)
            Gleisplan = Nothing
        End If
    End Sub
 
    Private Sub btnKillBitmap_Click(sender As Object, e As EventArgs) Handles _
      btnKillBitmap.Click
        DeleteBitmap()
    End Sub
 
    Private Sub btnCreateBitmap_Click(sender As Object, e As EventArgs) Handles _
      btnCreateBitmap.Click
        CreateBitmap()
    End Sub
 
    Private Sub btnSaveBitmap_Click(sender As Object, e As EventArgs) Handles _
      btnSaveBitmap.Click
        SaveBitmap()
    End Sub
End Class

Zitat:

Nach der Übernahme der Bitmap in die PictureBox lösche ich die Bitmap mit "Gleisplan = Nothing". Bei deutlich kleineren Bitmaps funktioniert das.

Zitat:

Vor dem Löschen des letzten Verweises auf die Bitmap MUSS Dispose gerufen werden, weil sonst keine Freigabe des Bild-Speichers und der Graphik-Ressourcen erfolgt.

Zitat:

Es spielt keine Rolle, ob das Projekt als 32- oder 64-Bit kompiliert wird, weil die Verwaltung der Graphikressourcen in Windows.Forms die gleichen Windows-Apis nutzt.

Zitat:

Ob eine Bitmap zu einem bestimmten Zeitpunkt tatsächlich angelegt werden kann, hängt davon ab, ob der dadurch angeforderte zusammenhängende Hauptspeicher-Block verfügbar ist. Ist der Speicher durch andere Anwendungen fragmentiert worden, scheitert die Erstellung der Bitmap. Das kann zu einer Argument-Ausnahme führen, nicht unbedingt zu einer Speichermangel-Ausnahme. Es ist also nicht genau vorherzusagen, ob genügend Speicher verfügbar ist.

Zitat:

Was genau verstehst Du unter "direkt in eine Picturebox zeichnen", CreateGraphics?

  Private Sub PictureBox1_Paint(sender As Object, e As PaintEventArgs) Handles _
    PictureBox1.Paint
    Dim g As Graphics = e.Graphics
    g.SmoothingMode = SmoothingMode.HighQuality
    g.DrawLine(Pens.Red, 5, 5, 100, 100)
    g.DrawLine(Pens.Blue, 25, 5, 200, 100)
  End Sub

    Private Sub CreateBitmap()
 
 
        DeleteBitmap() 'Freigabe sicher stellen
 
        Dim Gpx, GPy, x1, y1, x2, y2 As Integer
        Gpx = 24361
        GPy = 5966
 
        Try
            Gleisplan = New Bitmap(Gpx, GPy,
             Imaging.PixelFormat.Format32bppArgb)
 
        Catch ex As Exception
            MsgBox("Bitmap kann nicht erstellt werden" & vbCrLf & ex.Message)
            DeleteBitmap()
            Exit Sub
        End Try
 
        pb.Image = Gleisplan
 
        Using g As Graphics = Graphics.FromImage(Gleisplan),
                pn As New System.Drawing.Pen(Color.Blue, 8)
            g.Clear(Color.Yellow)
            For i As Integer = 0 To 10
                x2 = x1
                y2 = y1
                x1 = CInt(rndm.NextDouble() * Gpx)
                y1 = CInt(rndm.NextDouble() * GPy)
                g.DrawLine(pn, x1, y1, x2, y2)
            Next i
        End Using
 
    End Sub