''' <summary>JPEGs im Ordner als Thumbnails laden</summary>
    ''' <param name="PicPath">Ordner mit JPEG-Dateien</param>
    ''' <param name="width">Thumbnails: maximale Breite (10-400 Pixel)</param>
    ''' <param name="height">Thumbnails: maximale Höhe (10-400 Pixel</param>
    ''' <returns>Bitmap-Array mit Thumbnails (oder NOTHING)</returns>
    Public Function GetPics(ByVal PicPath As String, _
        Optional ByVal width As Integer = 300, _
        Optional ByVal height As Integer = 300) As Bitmap()
 
        'Parameter prüfen
        If PicPath Is Nothing Then Return Nothing
        If Not IO.Directory.Exists(PicPath) Then Return Nothing
 
        If width < 10 Or width > 400 Then Return Nothing
        If height < 10 Or height > 400 Then Return Nothing
 
        Try
            'Bilderliste für Rückgabe
            Dim pics As New List(Of Bitmap)
 
            'JPEG-Dateien im Ordner ermitteln und bearbeiten
            For Each file As String In My.Computer.FileSystem.GetFiles _
                (PicPath, FileIO.SearchOption.SearchTopLevelOnly, "*.jpg", _
                "*.jpeg")
 
 
                Using bmp_loaded As New Bitmap(file) 'Bild-Datei laden
                    With bmp_loaded
                        'Thumbnail-Größe ermitteln
                        Dim twidth As Integer = width
                        Dim theight As Integer = CInt(.Height * width / .Width)
 
                        If theight > height Then
                            theight = height
                            twidth = CInt(.Width * height / .Height)
                        End If
 
                        'Thumbnail erstellen                   
                        Using thumbnail As New Bitmap(twidth, theight),
                            gr As Graphics = Graphics.FromImage(thumbnail)
                            gr.DrawImage(bmp_loaded, 0, 0, twidth, theight)
                            'Thumbnail-Kopie in der Liste anhängen 
                            pics.Add(CType(thumbnail.Clone, Bitmap))
                        End Using 'Thumbnail freigeben
                    End With
                End Using 'bmp_loaded freigeben
            Next file 'JPEG-File
 
            'Thumbnails als Array zurückgeben
            Return pics.ToArray
        Catch
            'Fehler beim Laden des Bildes
            Return Nothing
        End Try
    End Function

Dim thumbnails() As Bitmap = GetPics("C:\Pictures", 300, 300)

Public Class frmThumbs
 
    Dim mnuMain As New MenuStrip With {.Parent = Me}
    Dim fbd As New FolderBrowserDialog With _
       {.Description = "Ordner mit Bilddateien", _
        .ShowNewFolderButton = False}
 
    Dim pb_list As New List(Of PictureBox) 'Liste für Pictureboxen
 
    Private Sub frmThumbs_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Dim th_Width As Integer = 200
        Me.Size = New Size(th_Width * 4 + 10, th_Width * 4 + 80)
 
        mnuMain.Items.Add _
        ("Bilder laden", Nothing, AddressOf mnuLoad_click)
 
        'Erstellung/Positionierung der Pictureboxen in Liste
        Dim z As Integer
        For i As Integer = 0 To 3
            For k As Integer = 0 To 3
                z += 1
 
                Dim pb As New PictureBox With _
                    {.Parent = Me, .Top = i * th_Width + 50, _
                     .Left = k * th_Width, _
                     .Width = th_Width, .Height = th_Width, _
                    .BorderStyle = BorderStyle.FixedSingle,
                    .SizeMode = PictureBoxSizeMode.Zoom, _
                    .Tag = z}
 
                AddHandler pb.Click, AddressOf pbox_click
 
                pb_list.Add(pb)
            Next k
        Next i
 
    End Sub
 
    Private Sub pbox_click(ByVal sender As Object, e As EventArgs)
        Dim pb As PictureBox = CType(sender, PictureBox)
        Dim z As Integer = CInt(pb.Tag)
        MsgBox(CStr(z) & " ist abgeclickt")
 
        'Hier Code für Bildbearbeitung einfügen
    End Sub
 
    Private Sub mnuload_click(ByVal sender As Object, e As EventArgs)
 
        'Wahl eines Ordners und Erstellung der Thumbnails
        With fbd
            If .ShowDialog = Windows.Forms.DialogResult.Cancel Then Exit Sub
 
            Me.Refresh()
            Me.Cursor = Cursors.WaitCursor
 
            Dim thumbnails() As Bitmap = GetPics(.SelectedPath, 300, 300)
 
            If thumbnails Is Nothing _
               OrElse thumbnails.Length = 0 Then Exit Sub
 
            For i As Integer = 0 To pb_list.Count - 1
                If i < thumbnails.Length Then
                    'Thumbnails in Pictureboxen anzeigen
                    pb_list(i).Image = thumbnails(i)
                End If
            Next i
 
            Me.Cursor = Cursors.Default
        End With
    End Sub
 
'Hier restlichen Code einfügen

Public Class frmThumbsII
 
    Dim mnuMain As New MenuStrip With {.Parent = Me}
    Dim fbd As New FolderBrowserDialog With _
    {.Description = "Ordner mit Bilddateien", _
     .ShowNewFolderButton = False}
 
    Dim pb_list As New List(Of PictureBox)
    Dim pics As New List(Of IO.MemoryStream)
 
    Dim WithEvents trbPics As New TrackBar With _
        {.Parent = Me, .Dock = DockStyle.Bottom}
 
    Dim WithEvents bgw As New System.ComponentModel.BackgroundWorker
 
    Dim PicPath As String
 
    Private Sub frmThumbsII_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Me.FormBorderStyle = Windows.Forms.FormBorderStyle.FixedSingle
        Dim th_Width As Integer = 150
        Me.Size = New Size(th_Width * 4 + 10, th_Width * 4 + 130)
        trbPics.Height = 50 : trbPics.Top = Me.Height - 80
 
        mnuMain.Items.Add("Bilder laden", Nothing, AddressOf mnuload_click)
 
        Dim z As Integer
        For i As Integer = 0 To 3
            For k As Integer = 0 To 3
                z += 1
                Dim pb As New PictureBox With _
                    {.Parent = Me, .Top = i * th_Width + 50, .Left = k * _
                    th_Width, _
                     .Width = th_Width, .Height = th_Width, _
                    .BorderStyle = BorderStyle.FixedSingle,
                    .SizeMode = PictureBoxSizeMode.Zoom, .Tag = z}
                AddHandler pb.Click, AddressOf pbox_click
                pb_list.Add(pb)
            Next k
        Next i
 
    End Sub
 
    Private Sub mnuload_click(ByVal sender As Object, e As EventArgs)
        With fbd
            If .ShowDialog = Windows.Forms.DialogResult.Cancel Then Exit Sub
            Me.UseWaitCursor = True
            trbPics.Visible = False
            Me.Refresh()
            PicPath = .SelectedPath
            bgw.RunWorkerAsync()
        End With
    End Sub
 
    Private Sub pbox_click(ByVal sender As Object, e As EventArgs)
        Dim pb As PictureBox = CType(sender, PictureBox)
        Dim z As Integer = CInt(pb.Tag)
        MsgBox("Bild " & CStr(z) & " ist angeclickt")
    End Sub
 
    Private Sub trbPics_ValueChanged(sender As Object, _
        e As System.EventArgs) Handles trbPics.ValueChanged
        Static IsBusy As Boolean
        If IsBusy Then Exit Sub
        IsBusy = True
        For i As Integer = 0 To pb_list.Count - 1
            With pb_list(i)
                If .Image IsNot Nothing Then
                    .Image = Nothing : .Tag = -1
                End If
                Dim index As Integer = trbPics.Value + i
                If index < pics.Count Then
                    .Image = Image.FromStream(pics(index))
                    .Tag = trbPics.Value + i
                End If
                .Refresh()
            End With
        Next i
        IsBusy = False
    End Sub
 
    Private Sub bgw_DoWork(sender As Object, _
        e As System.ComponentModel.DoWorkEventArgs) Handles bgw.DoWork
        pics.Clear()
        For Each file As String In My.Computer.FileSystem.GetFiles(PicPath, _
                    FileIO.SearchOption.SearchTopLevelOnly, "*.jpg")
            Using fs As New IO.FileStream(file, IO.FileMode.Open, _
              IO.FileAccess.Read)
                Dim buffer(CInt(fs.Length - 1)) As Byte
                fs.Read(buffer, 0, buffer.Length)
                pics.Add(New IO.MemoryStream(buffer))
            End Using
        Next file
    End Sub
 
    Private Sub bgw_RunWorkerCompleted(sender As Object, _
        e As System.ComponentModel.RunWorkerCompletedEventArgs) _
        Handles bgw.RunWorkerCompleted
        With trbPics
            .Value = 0
            .Visible = pics.Count > pb_list.Count
            If .Visible Then .Maximum = pics.Count - pb_list.Count
            .TickFrequency = Math.Max(1, pics.Count \ 10)
        End With
        Me.Text = CStr(pics.Count) & " JPEGs sind geladen"
        trbPics_ValueChanged(Me, Nothing)
        Me.UseWaitCursor = False
    End Sub
End Class