Benutzergruppen und ihre Benutzer Mit der ADSI-Schnittstelle lassen sich auf einfache Weise alle Benutzergruppen und deren Benutzer ermitteln.
Autor:   Dieter Otter	Bewertung:	Views:  18.011
www.tools4vb.de	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Heute möchten wir Ihnen zeigen, wie sich mit Hilfe der ADSI-Schnittstelle (ADSI = Active Directory Service Interface) alle Benutzergruppen und deren Benutzer ermitteln lassen.

Benutzergruppen des lokalen PC's ermitteln

Dim oADSI As Object
Dim oGroup As Object
Dim sDomain As String
 
' Fehlerbehandlung aktivieren
On Error GoTo ErrHandler
 
' lokaler PC
sDomain = "."
 
' ADSI Container-Objekt erstellen
Set oADSI = GetObject("WinNT://" & sDomain)
 
' Benutzergruppen filtern
oADSI.Filter = Array("Group")
 
' alle Benutzergruppen auflisten
For Each oGroup In oADSI
  Debug.Print oGroup.Name
Next
 
ErrHandler:
  ' Objekte zerstören
  Set oGroup = Nothing
  Set oADSI = Nothing

Alle Benutzer ermitteln, egal welcher Gruppe diese angehören

Dim oADSI As Object
Dim oUser As Object
Dim sDomain As String
 
' Fehlerbehandlung aktivieren
On Error GoTo ErrHandler
 
' lokaler PC
sDomain = "."
 
' ADSI Container-Objekt erstellen
Set oADSI = GetObject("WinNT://.")
 
' Benutzer filtern
oADSI.Filter = Array("User")
 
' alle Benutzernamen auflisten
For Each oUser In oADSI
  Debug.Print oUser.Name
Next
 
ErrHandler:
  ' Objekte zerstören
  Set oUser = Nothing
  Set oADSI = Nothing

Alle Benutzer einer bestimmten Benutzergruppe auflisten

Dim oGroup As Object
Dim oMember As Object
Dim sDomain As String
Dim sGroup As String
 
' Fehlerbehandlung aktivieren
On Error GoTo ErrHandler
 
' lokaler PC
sDomain = "."
 
' Beutzergruppe "Administratoren"
sGroup = "Administratoren"
 
' Gruppe der Administratoren für den lokalen Rechner
Set oGroup = GetObject("WinNT://" & sDomain & "/" & sGroup & ",group")
 
' alle User in der Administratoren-Gruppe auflisten
For Each oMember In oGroup.Members
  Debug.Print oMember.Name
Next
 
ErrHandler:
  ' Objekte zerstören
  Set oMember = Nothing
  Set oGroup = Nothing

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.