Netzwerkverbindung autom. überwachen Unter VB.NET 2005 lässt sich die Netzwerkverfügbarkeit sehr einfach überwachen.
Autor:   Dieter Otter	Bewertung:	Views:  22.926
www.tools4vb.de	System:  WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Für die Überwachung der Verfügbarkeit einer Netzwerkverbindung gibt es in VB.NET 2005 ein spezielles Ereignis namens NetworkAvailabilityChanged. Dieses Ereignis finden Sie in den ApplicationEvents (Doppelklick auf "MyProject" im Projektmappen-Explorer und Klick auf die Schaltfläche "Anwendungsereignisse anzeigen" im Registrer "Anwendung").

Das Ereignis NetworkAvailabilityChanged wird immer dann ausgelöst, wenn sich der Status der Netzwerkverbindung geändert hat. Somit können Sie gezielt darauf reagieren.

Beispiel:
Platzieren Sie auf die Form (Form1) ein Label-Control (Label1) und fügen nachfolgenden Code in den Codeteil der Form ein:

Public Class Form1
  Private Sub Form1_Load(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles MyBase.Load
 
    ' Netzwerkverbindung prüfen
    Try
      ShowNetworkState(My.Computer.Network.IsAvailable)
    Catch ex As Exception
      ShowNetworkState(False)
    End Try
  End Sub
 
  Public Sub ShowNetworkState(ByVal bNetAvail As Boolean)
    With Me.Label1
      If bNetAvail Then
        ' Netzwerkverbindung verfügbar
        .Text = "Netzwerkverbindung OK"
        .BackColor = Color.Green
        .ForeColor = Color.Black
      Else
        ' keine Netzwerkverbindung
        .Text = "keine Netzwerkverbindung"
        .BackColor = Color.Red
        .ForeColor = Color.White
      End If
    End With
  End Sub
End Class

Doppelklicken Sie im Projektmappen-Explorer auf den Eintrag "My Project" und klicken dann auf die Schaltfläche "Anwendungsereignisse anzeigen" im Register "Anwendung". Fügen Sie nachfolgenden Code in das ApplicationEvents-Modul ein:

Namespace My
 
  ...
 
  Partial Friend Class MyApplication
 
    Private Sub MyApplication_NetworkAvailabilityChanged( _
      ByVal sender As Object, _
      ByVal e As Microsoft.VisualBasic.Devices.NetworkAvailableEventArgs) _
      Handles Me.NetworkAvailabilityChanged
 
      ' Status der Netzwerkverbindung hat sich geändert
      Try
        If e.IsNetworkAvailable Then
          ' Netzwerkverbindung ist verfügbar
          My.Forms.Form1.ShowNetworkState(True)
        Else
          ' Netzwerkverbindung wurde getrennt
          My.Forms.Form1.ShowNetworkState(False)
        End If
      Catch ex As Exception
 
      End Try
    End Sub
  End Class
 
End Namespace

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.