vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Blitzschnelles Erstellen von grafischen Diagrammen!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: HTML/Internet/Netzwerk · Netzwerk   |   VB-Versionen: VB5, VB627.03.03
Netzwerk-Konfiguration via WMI auslesen

Sie wollten schon immer Ihre Netzwerkkonfiguration auslesen, um sie programmtechnisch verwursten zu können?

Autor:   Gerhard KuklauBewertung:     [ Jetzt bewerten ]Views:  49.657 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Sie wollten schon immer Ihre Netzwerkkonfiguration auslesen, um sie programmtechnisch verwursten zu können?

Dann öffnen Sie ein neues Projekt, platzieren auf der Form eine ListBox, und fügen in der Form folgenden Code ein:

Private Sub getWMI_Info()
  Dim oAdapters As Object
  Dim oAdapter As Object
 
  ' Fehlerbehandlung aktivieren
  On Error GoTo Fehler_WMI
 
  ' Computer-Name
  List1.AddItem "Name:" & vbTab & Environ$("computername")
 
  ' alle verfügbaren Netzwerk-Adapter mit IP-Adresse  
  Set oAdapters = GetObject("winmgmts:").execquery( _
    "SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
 
  ' Objekte durchlaufen
  For Each oAdapter In oAdapters
    List1.AddItem ""
 
 
    With oAdapter
      ' MAC-Adresse
      List1.AddItem "MAC:" & vbTab & vbTab & .MACAddress
 
      ' IP-Adresse
      List1.AddItem "IP:" & vbTab & vbTab & Join(.IPAddress)
 
      ' SubNet-Masks
      List1.AddItem "MASK:" & vbTab & vbTab & Join(.IPSubnet)
 
      ' Default-Gateways
      If Not IsNull(.DefaultIPGateway) Then
        List1.AddItem "GATE:" & vbTab & vbTab & Join(.DefaultIPGateway)
      End If
 
      ' DNS - Primary/Secondary
      List1.AddItem "DNS:" & vbTab & vbTab & .DNSHostName
 
      ' WINS - Primary
      If .WINSPrimaryServer <> "" Then 
        List1.AddItem "WINS Primary:" & vbTab & .WINSPrimaryServer
      End If
 
      ' WINS - Secondary
      If .WINSSecondaryServer <> "" Then 
        List1.AddItem "WINS:" & vbTab & .WINSSecondaryServer
      End If
    End With
  Next        
  On Error GoTo 0
  Exit Sub
 
Fehler_WMI:
  MsgBox "Fehler: " & Err.Number & vbTab & Err.Description, vbCritical
  Resume Next    
End Sub

Nun müssen Sie im Form_Load nur noch die Prozedur getWMI_Info aufrufen und schon werden Sie mit Ihren aktuell eingestellten Netzwerkparametern überrascht.

  • MAC-Adresse,
  • IP-Adresse,
  • SubNet-Mask,
  • Default Gateway,
  • DNS Server (Primary + Secondary),
  • WINS Server (Primary + Secondary)

    Private Sub Form_Load()
      getWMI_Info
    End Sub

    Um sicher zu gehen, dass WMI auf Ihrem Computer installiert ist, können Sie sich mit folgendem Tipp vergewissern:

     Ist WMI installiert?
     

  • Dieser Tipp wurde bereits 49.657 mal aufgerufen.

    Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

    Über diesen Tipp im Forum diskutieren
    Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

    Neue Diskussion eröffnen

    nach obenzurück


    Anzeige

    Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
    (einschl. Beispielprojekt!)

    Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
    - nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
    - Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
    Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
     
       

    Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
    Alle Rechte vorbehalten.
    Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

    Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel