Selektierte Zeile umrahmen (DatagridView) Die vorgestellte Funktion erlaubt es, die selektierte Zeile mit einem Rechteck zu umrahmen und damit zu kennzeichnen.
Autor:   Dietrich Herrmann	Bewertung:     [ Jetzt bewerten ]	Views:  14.414
ohne Homepage	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 2 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.5 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Anders als in meinem Tipp  Selektierte Zeile unterstreichen (DatagridView) realisiert die folgende Funktion das Umrahmen der selektierten Zeile eines DGV.

Die Vorgehensweise ist in diesem Fall etwas einfacher, wie wir sehen werden.
Die Funktion drawRectOnDGV wird nur einfach im RowPostPaint-Ereignis des DGV aufgerufen. Sie benötigt ebenfalls die Funktion calcDGVWidth als Hilfsfunktion (siehe oben genannter Tipp).

''' <summary>
''' Zeichnen eines Rechtecks um die selektierte Zeile eines Datagridview
''' </summary>
''' <param name="theDGV">das DatagridView</param>
''' <param name="lineWidth">die Linienstärke</param>
''' <param name="lineColor">die Linienfarbe</param>
''' <param name="e">DataGridViewRowPostPaintEventArgs des RowPostPaint-Ereignisses</param>
Public Sub drawRectOnDGV(ByVal theDGV As DataGridView, _
  ByVal lineWidth As Short, _
  ByVal lineColor As Color, _
  ByVal e As DataGridViewRowPostPaintEventArgs)
 
  ' Anwenden im RowPostPaint-Ereignis des betreffenden Datagridview
  Dim rect As Rectangle
  With theDGV
    If .Rows(e.RowIndex).Selected Then  ' ist die Zeile selektiert?
      rect = .GetRowDisplayRectangle(e.RowIndex, False) ' das Rechteck der aktuellen Zeile
      ' Rechteck für den Rahmen erzeugen
      Dim rec As Rectangle = New Rectangle(rect.X + .RowHeadersWidth, rect.Y, _
      calcDGVWidth(theDGV) - .RowHeadersWidth - 1, rect.Height - 1)
      ' Zeichnen des Rahmens
      ControlPaint.DrawBorder(e.Graphics, rec, _
        lineColor, lineWidth, ButtonBorderStyle.Solid, _
        lineColor, lineWidth, ButtonBorderStyle.Solid, _
        lineColor, lineWidth, ButtonBorderStyle.Solid, _
        lineColor, lineWidth, ButtonBorderStyle.Solid)
    End If
  End With
End Sub

''' <summary>
''' Berechnen der aktuellen Breite eines Datagridview 
''' </summary>
''' <param name="theDGV">das DatagridView</param>
''' <returns>Breite des DatagridView</returns>
Public Function calcDGVWidth(ByVal theDGV As DataGridView) As Integer
  Dim theWidth As Integer
  With theDGV
    For Each c As DataGridViewColumn In .Columns
      If c.Visible = True Then theWidth += c.Width ' nur sichtbare Spaltenbreiten addieren
    Next
    If .RowHeadersVisible Then theWidth += .RowHeadersWidth
    If .Controls(1).Visible Then    ' ist die vertikale Scrollbar aktuell sichtbar?
      theWidth += SystemInformation.VerticalScrollBarWidth  ' Breite der Scrollbar
    End If
  End With
  Return theWidth
End Function

Der Code ist gut selbsterklärend, denke ich.

Aufrufbeispiel:

Private Sub DataGridView1_RowPostPaint(ByVal sender As Object, _
  ByVal e As System.Windows.Forms.DataGridViewRowPostPaintEventArgs) _
  Handles DataGridView1.RowPostPaint
 
  drawRectOnDGV(DataGridView1, 2, Color.Red, e)
End Sub