vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Top-Preis! AP-Access-Tools-CD Volume 1  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2015
 
zurück
Rubrik: COM/OLE/Registry/DLL · Sonstiges   |   VB-Versionen: VB4, VB5, VB608.11.01
DLL, EXE, OLB und TLB per Sourcecode registrieren

Im Gegensatz zu unserem früheren Tipp lassen sich mit dieser Routine jetzt auch ActiveX-EXE Dateien per Sourcecode registrieren.

Autor:   Manfred LuhmannBewertung:     [ Jetzt bewerten ]Views:  29.682 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Summer-Special bei Tools & Components!
Gute Laune Sommer bei Tools & Components
Top Summer-Special - Sparen Sie teilweise über 100,- EUR
Alle sev-Entwicklerkomponenten und Komplettpakete jetzt bis zu 25% reduziert!
zum Beispiel:
  • Developer CD nur 455,- EUR statt 569,- EUR
  • sevDTA 2.0 nur 224,30 EUR statt 299,- EUR
  •  
  • vb@rchiv   Vol.6 nur 18,70 EUR statt 24,95 EUR
  • sevCoolbar 3.0 nur 58,70 EUR statt 69,- EUR
  • - Werbung -Und viele weitere Angebote           Aktionspreise nur für kurze Zeit gültig

    In einem unserer ersten Tipps  Dateien per Quellcode registrieren haben wir Ihnen gezeigt, wie sich vor allem ActiveX-DLLs per Sourcecode registrieren lassen, um so den Fehler 429 Objekterstellung durch ActiveX-Komponente nicht möglich zu vermeiden.

    Mit dem nachfolgenden Modul ist es jetzt auch möglich, ActiveX-EXE Dateien per Sourcecode zu registrieren.

    Option Explicit
    ' -------------------------------------------------------
    ' 
    ' Mit der Funktion "RegisterFile" können dll,exe,olb
    ' und tlb-Dateien registriert und deregistriert werden.
    ' 
    ' Aufgerufen wird das Programm \windows\regtlib.exe
    ' Luhmann, 07.11.01
    ' 
    ' -------------------------------------------------------
     
    Private Declare Function CloseHandle Lib "kernel32" ( _
      ByVal hObject As Long) As Long
     
    Private Declare Function GetExitCodeProcess Lib "kernel32" ( _
      ByVal hProcess As Long, _
      lpExitCode As Long) As Long
     
    Private Declare Function OpenProcess Lib "kernel32" ( _
      ByVal dwDesiredAccess As Long, _
      ByVal bInheritHandle As Boolean, _
      ByVal dwProcessID As Long) As Long
     
    Private Declare Function WaitForSingleObject Lib "kernel32" ( _
      ByVal hHandle As Long, _
      ByVal dwMilliseconds As Long) As Long
     
    ' Datei registrieren/deregistrieren
    Public Function RegisterFile(ByVal Filename As String, _
      Optional ByVal Register As Boolean = True) As Long
     
      Const PROCESS_QUERY_INFORMATION = &H400
     
      Dim CmdLine As String
      Dim dwProcessID As Long
      Dim hProcess As Long
     
      If Register Then
        ' Datei registrieren
        CmdLine = "regtlib " & Filename
      Else
        ' Datei deregistrieren
        CmdLine = "regtlib -u " & Filename
      End If
     
      ' Prozess-ID
      dwProcessID = VBA.Interaction.Shell(CmdLine)
     
      ' Prozess öffnen
      hProcess = OpenProcess(PROCESS_QUERY_INFORMATION, _
        False, dwProcessID)
     
      If hProcess = 0 Then
        ' Fehler!
        RegisterFile = Err.LastDllError
        Call ErrMsg("OpenProcess " & CmdLine, RegisterFile)
        Exit Function
      End If
     
      ' Datei registrieren/deregistrieren
      Call WaitForSingleObject(hProcess, 1000)
      Call GetExitCodeProcess(hProcess, RegisterFile)
      If RegisterFile <> 0 Then _
        Call ErrMsg("GetExitCodeProcess " & CmdLine, RegisterFile)
     
      ' Prozess schliessen
      Call CloseHandle(hProcess)
    End Function
     
    ' Fehhlermeldung auswerten
    Private Sub ErrMsg(ByVal Info As String, _
      ByVal Errno As Long)
     
      Dim Errtext As String
     
      Select Case Errno
        Case 0: Errtext = " ok"
        Case 3: Errtext = " File not found or not a Typelib"
        Case 5: Errtext = " File was not registered"
        Case &H103: Errtext = "Process still active"
        Case Else: Errtext = "??"
      End Select
     
      MsgBox Info & vbCr & "Error=" & Errno & Errtext, _
        vbExclamation, VB.App.EXEName
    End Sub

    Dieser Tipp wurde bereits 29.682 mal aufgerufen.

    Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

    Über diesen Tipp im Forum diskutieren
    Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

    Neue Diskussion eröffnen

    nach obenzurück


    Anzeige

    Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
    (einschl. Beispielprojekt!)

    Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
    - nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
    - Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
    Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
     
       

    Druckansicht Druckansicht Copyright ©2000-2015 vb@rchiv Dieter Otter
    Alle Rechte vorbehalten.
    Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

    Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel