vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevAniGif - als kostenlose Vollversion auf unserer vb@rchiv CD Vol.5  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2021
 
zurück
Rubrik: Menüs22.03.05
CreatePopupMenu-Funktion

Diese Funktion erstellt ein Popupmenü und gibt das Handle zu diesem zurück.

Betriebssystem:  Win95, Win98, WinNT 3.1, Win2000, WinMEViews:  11.186 

Deklaration:

Declare Function CreatePopupMenu Lib "user32.dll" () As Long

Beschreibung:
Diese Funktion erstellt ein Popupmenü und gibt das Handle zu diesem zurück.

Parameter:
keine

Rückgabewert:
Ist die Funktion erfolgreich, so liefert sie das Handle zu dem neu erstelltem Popupmenü, andernfalls ist die Rückgabe "0". Erweiterte Fehlerinformationen können mittels der GetLastError-Funktion ermittelt werden.

Beispiel:

Private Declare Function CreatePopupMenu Lib "user32.dll" () As Long
Private Declare Function DestroyMenu Lib "user32.dll" ( _
  ByVal hMenu As Long)  As Long
Private Declare Function InsertMenuItem Lib "user32.dll" _
  Alias "InsertMenuItemA" ( _
  ByVal hMenu As Long, _
  ByVal uItem As Long, _
  ByVal fByPosition As Long, _
  lpmii As MENUITEMINFO) As Long
Private Declare Function TrackPopupMenu Lib "user32.dll" ( _
  ByVal hMenu As Long, _
  ByVal uFlags As Long, _
  ByVal x As Long, _
  ByVal y As Long, _
  ByVal nReserved As Long, _
  ByVal hwnd As Long, _
  ByVal prcRect As Long) As Long
Private Declare Function GetWindowRect Lib "user32.dll" ( _
  ByVal hwnd As Long, _
  lpRect As RECT) As Long
 
Private Type RECT
  left As Long
  top As Long
  right As Long
  bottom As Long
End Type
 
Private Type MENUITEMINFO
  cbSize As Long
  fMask As Long
  fType As Long
  fState As Long
  wID As Long
  hSubMenu As Long
  hbmpChecked As Long
  hbmpUnchecked As Long
  dwItemData As Long
  dwTypeData As String
  cch As Long
End Type
 
' MENUITEMINFO fMask-Konstanten
Private Const MIIM_STATE = &H1 ' Benutzt die fState Optionen
Private Const MIIM_ID = &H2 ' Benutzt die wID Option
Private Const MIIM_SUBMENU = &H4 ' Benutzt die hSubMenu Option
Private Const MIIM_CHECKMARKS = &H8 ' Benutzt die hbmpChecked und hbmpUnchecked Optionen
Private Const MIIM_DATA = &H20 ' Benutzt die dwItemDate Option
Private Const MIIM_TYPE = &H10 ' Benutzt die dwTypeData Option
 
' MENUITEMINFO fType-Konstanten
Private Const MFT_BITMAP = &H4 ' Zeigt ein Bitmap im Menü an. Das Handle des  _
' Bitmaps muss in dwTypeData übergeben werden und cch wird Ignoriert. Kann 
' nicht mit MFT_SEPARATOR oder MFT_STRING kombiniert werden
Private Const MFT_MENUBARBREAK = &H20 ' Platziert das Menü in einer neuen Zeile oder Spalte und 
' zeichnet über und unter dem Eintrag einen Separator
Private Const MFT_MENUBREAK = &H40 ' Das gleiche wie MFT_MENUBARBREAK nur ohne Separator
Private Const MFT_OWNERDRAW = &H100 ' Überlässt das Neuzeichnen des Menüs dem Fenster
Private Const MFT_RADIOCHECK = &H200 ' Zeigt einen Radiobutton als Checked / Unchecked an
Private Const MFT_RIGHTJUSTIFY = &H4000 ' Richtet ein Menü rechtsbündig aus
Private Const MFT_RIGHTORDER = &H2000 ' (Win 9x, 2000) Die Menüs platzieren sich rechts voneinander und  
' es wird Text von rechts nach links unterstützt
Private Const MFT_SEPARATOR = &H800 ' Zeichnet eine Horizontale Linie in den  Menüeintrag, 
' dwTypeData und cch werden Ignoriert. Kann nicht mit  
' MFT_BITMAP oder MFT_STRING kombiniert werden
Private Const MFT_STRING = &H0 ' Der Menüeintrag wird mit einem String gefüllt, dwTypeData ist der 
' String der angezeigt werden soll und cch die Länge des Strings. 
' Kann nicht mit MFT_BITMAP oder MFT_SEPARATOR Kombiniert werden 
 
' MENUITEMINFO fState-Konstanten
Private Const MFS_CHECKED = &H8 ' Menüeintrag ist Markiert
Private Const MFS_DEFAULT = &H1000 ' Menüeintrag ist die Standard Auswahl
Private Const MFS_DISABLED = &H2 ' Menüeintrag ist Disabled
Private Const MFS_ENABLED = &H0 ' Menüeintrag ist Enabled
Private Const MFS_GRAYED = &H1 ' Menüeintrag ist Grau und Disabled
Private Const MFS_HILITE = &H80 ' Menüeintrag hat die Selektierung
Private Const MFS_UNCHECKED = &H0 ' Menüeintrag ist nicht Markiert
Private Const MFS_UNHILITE = &H0 ' Menüeintrag hat nicht die Selektierung
 
' TrackPopupmenu uFlags-Konstanten
Private Const TPM_CENTERALIGN = &H4 ' Positioniert das Menü Horizontal in der Mitte von x
Private Const TPM_LEFTALIGN = &H0 ' Positioniert das Menü Horizontal mit dem linken Rand auf x
Private Const TPM_RIGHTALIGN = &H8 ' Positioniert das Menü Horizontal mit dem Rechten Rand auf x
Private Const TPM_BOTTOMALIGN = &H20 ' Positioniert das Menü mit dem unteren Rand auf y
Private Const TPM_TOPALIGN = &H0 ' Positioniert das Menü mit dem oberen Rand auf y
Private Const TPM_VCENTERALIGN = &H10 ' Positioniert das Menü Vertikal in der Mitte von y
Private Const TPM_NONOTIFY = &H80 ' Sendet kein WM_COMMAND an das  
' Elternfenster des Menüs bei Ereignissen
Private Const TPM_RETURNCMD = &H100 ' Die Funktion gibt den ID des Menüs  
' zurück, welches gewählt wurde
Private Const TPM_LEFTBUTTON = &H0 ' Erlaubt dem Benutzer nur das Markieren  
' der Einträge über die Linke Maustaste und der Tastatur
Private Const TPM_RIGHTBUTTON = &H2 ' Erlaubt dem Benutzer die Einträge mit  
' jedem Mausbutton und der Tastatur zu wählen
 
Dim hPopupMenu As Long
Dim Menüeintrag(1 To 2) As MENUITEMINFO
' Popupmenü anzeigen und auswerten
Private Sub Command1_Click()
  Dim Retval As Long, Flags As Long, CmdPos As RECT
 
  ' Position des Fensters ermitteln
  GetWindowRect Command1.hwnd, CmdPos
 
  ' Menü anzeigen
  Flags = TPM_LEFTBUTTON Or TPM_TOPALIGN Or TPM_NONOTIFY Or TPM_RETURNCMD
  Retval = TrackPopupMenu(hPopupMenu, Flags, CmdPos.right,  _
  CmdPos.bottom, 0&, Me.hwnd, 0&)
 
  ' Gewähltes Menü ausgeben, wenn eines gewählt wurde
  If Retval << 0 Then
    MsgBox "Sie haben auf """ &  _
    Replace(Menüeintrag(Retval).dwTypeData, "&", "", 1, 1) & """ gedrückt" 
  End If
End Sub
' Erstellt das Popupmenü und speichert das Handle in hPopupMenu
Private Sub Form_Load()
  Dim Retval As Long
 
  ' Popup Menü erstellen
  hPopupMenu = CreatePopupMenu()
 
  ' Menüeintrag hinzufügen ("&Einfügen")
  With Menüeintrag(1)
    .cbSize = Len(Menüeintrag(1))
    .dwTypeData = "&Einfügen"
    .cch = Len(Trim$(.dwTypeData))
    .fMask = MIIM_TYPE Or MIIM_ID
    .fState = MFS_DEFAULT Or msf_hilite
    .fType = MFT_STRING
    .wID = 1
  End With
  Retval = InsertMenuItem(hPopupMenu, 0&, 0&, Menüeintrag(1))
  If Retval = 0 Then
    Debug.Print "Menüeintrag konnte nicht hinzugefügt werden: (Einfügen)." 
  End If
 
  ' Menüeintrag hinzufügen ("&Ausschneiden")
  With Menüeintrag(2)
    .cbSize = Len(Menüeintrag(2))
    .dwTypeData = "&Ausschneiden"
    .cch = Len(Trim$(.dwTypeData))
    .fMask = MIIM_TYPE Or MIIM_ID
    .fState = MFS_DEFAULT Or msf_hilite
    .fType = MFT_STRING
    .wID = 2
  End With
  Retval = InsertMenuItem(hPopupMenu, 0&, 0&, Menüeintrag(2))
  If Retval = 0 Then
    Debug.Print "Menüeintrag konnte nicht hinzugefügt werden: (Ausschneiden)." 
  End If
End Sub
' Popupmenü entfernen und Ressourcen freigeben
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  DestroyMenu hPopupMenu
End Sub

Diese Seite wurde bereits 11.186 mal aufgerufen.

nach obenzurück
 
   

Druckansicht Druckansicht Copyright ©2000-2021 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel