GetWindowText-Funktion Diese Funktion ermittelt den Text der Titelzeile eines Fensters (Caption-Eigenschaft).
Betriebssystem:  Win95, Win98, WinNT, Win2000, WinME	Views:  30.259

Beschreibung:
Diese Funktion ermittelt den Text der Titelzeile eines Fensters (Caption-Eigenschaft).

Deklaration:

Declare Function GetWindowText Lib "user32" _
  Alias "GetWindowTextA" ( _
  Byval hwnd As Long, _
  Byval lpString As String, _
  Byval cch As Long) As Long

Parameter:

hwnd	Erwartet das Fensterhandle des Fensters, dessen Titelleistentext ermittelt werden soll.
lpString	Erwartet einen Puffer, der mit dem Titelleistentext gefüllt wird.
cch	Erwartet die Länge in Bytes, die der Puffer groß ist. Die benötigte Größe kann man mit der GetWindowTextLength-Funktion ermitteln.

Rückgabewert:
Ist die Funktion erfolgreich, so enthält lpString den Text der Titelzeile. Als Funktions-Rückgabewert wird die Länge (Anzahl Zeichen) der Titelleiste zurückgegeben. Tritt ein Fehler auf, oder existiert kein Fenster mit dem angegebenen Fenster-Handle wird 0 zurückgegeben.

Beispiel:

Private Declare Function GetWindowTextLength Lib "user32" _
  Alias "GetWindowTextLengthA" ( _
  Byval hwnd As Long) As Long 
Private Declare Function GetWindowText Lib "user32" _
  Alias "GetWindowTextA" ( _
  Byval hwnd As Long, _
  Byval lpString As String, _
  Byval cch As Long) As Long 
Private Declare Function SetWindowText Lib "user32" _
  Alias "SetWindowTextA" ( _
  Byval hwnd As Long, _
  Byval lpString As String) As Long

Private Sub Command1_Click () 
  Dim Pufferlänge As Long, Puffer As String 
 
  ' Länge des Captiontextes ermitteln
  Pufferlänge = GetWindowTextLength(Me.hwnd) + 1 
  Puffer =Space(Pufferlänge) 
 
  ' Alte Captioneigenschaft auslesen und ausgeben
  Pufferlänge = GetWindowText(Me.hwnd, Puffer, Pufferlänge) 
  Debug.Print "Alter Caption Text: " & Left$(Puffer$, Pufferlänge) 
 
  ' Setzt die neue Caption eigenschaft
  SetWindowText Me.hwnd, "www.VBApiHelpLine.x2.nu" 
End Sub