SetComputerName-Funktion Ananlog zur Funktion GetComputerName kann mit dieser Funktion der Computername geändert werden.
Betriebssystem:  Win95, Win98, WinNT, Win2000, WinME	Views:  10.472

Beschreibung:
Ananlog zur Funktion GetComputerName kann mit dieser Funktion der Computername geändert werden.

Deklaration:

Declare Function SetComputerName Lib "kernel32" _
  Alias "SetComputerNameA" ( _
  ByVal lpComputerName As String) As Long

Parameter:

lpComputerName

Der neue Name (String) des Computers.

Rückgabewert:
War der Funktionsaufruf erfolgreich wird ein Wert ungleich 0 zurückgegeben. Trat ein Fehler auf, ist der Rückgabewert "0".

Hinweis:
Die Änderung des Computernamens wirkt sich erst nach einem System-Neustart aus.

Beispiel:

Private Declare Function SetComputerName Lib "kernel32" _
  Alias "SetComputerNameA" ( _
  ByVal lpComputerName As String) As Long
 
Private Declare Function GetComputerName Lib "kernel32.dll" _
  Alias "GetComputerNameA" ( _
  ByVal lpBuffer As String, _
  nSize As Long) As Long
 
Private Declare Function ExitWindowsEx Lib "user32" ( _
  ByVal uFlags As Long, _
  ByVal dwReserved As Long) As Long
 
Private Const EWX_REBOOT = 2

Private Sub Command1_Click()
  Dim lRet As Long
  Dim lpBuffer As String * 256
  Dim ComputerName As String
  Dim NeuerName As String
 
  ' bisherigen Computernamen ermitteln
  lRet = GetComputerName(lpBuffer, Len(lpBuffer))
  If lRet <> 0 Then
    ComputerName = Left$(lpBuffer, InStr(1, lpBuffer, vbNullChar) - 1)
 
    ' Eingabeaufforderung: Neuer Computername
    NeuerName = InputBox("Neuer Computername:", "Computernamen ändern", _
      ComputerName)
 
    If NeuerName <> "" And NeuerName <> ComputerName Then
      If SetComputerName(NeuerName) <> 0 Then
        ' Frage nach Neustart
        ExitWindowsEx EWX_REBOOT, 0&
      End If
    End If
  End If
End Sub