Zitat:

Du hattest meine Frage im Forum beantwortet. Könntest Du mir das programmieren. Für sagen wir mal 10.-€?

Option Explicit
 
Private Declare Function GetForegroundWindow Lib "user32" () As Long
 
Private Declare Function GetWindowText Lib "user32" _
  Alias "GetWindowTextA" ( _
  ByVal hwnd As Long, _
  ByVal lpString As String, _
  ByVal cch As Long) As Long
 
Private Declare Function GetWindowTextLength Lib "user32" _
  Alias "GetWindowTextLengthA" ( _
  ByVal hwnd As Long) As Long
 
Private Declare Function SetWindowText Lib "user32" _
  Alias "SetWindowTextA" ( _
  ByVal hwnd As Long, _
  ByVal lpString As String) As Long
 
Private Const sMyText = " - Irgendwas"

Private Sub Form_Load()
  ' Timer initialisieren
  Timer1.Interval = 50
  Timer1.Enabled = True
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  ' Beenden
  Timer1.Enabled = False
End Sub

Private Sub Timer1_Timer()
  Static nHWndOld As Long
  Dim nHWnd As Long
 
  ' Aktives Fenster ermitteln
  nHWnd = GetForegroundWindow()
  If nHWnd <> nHWndOld Then
    Dim sTitle As String
    Dim nLen As Long
 
    ' Handle merken
    nHWndOld = nHWnd
 
    ' aktuellen Fenstertext ermitteln
    nLen = GetWindowTextLength(nHWnd)
    sTitle = Space$(nLen)
    GetWindowText nHWnd, sTitle, nLen
 
    sTitle = Left$(sTitle, nLen - 1)
 
    ' Beinhaltet der Titel schon den Text?
    If Right$(sTitle, Len(sMyText)) <> sMyText Then
      ' Nein! Also hinzufügen
      SetWindowText nHWnd, sTitle & sMyText
    End If
  End If
End Sub

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de