''' <summary>Neuen Messwert anfügen (automatischer Zeitstempel) </summary>
    ''' <param name="vl">Messwert-Ausprägung</param>
    Public Function AddDataPoint(ByVal vl As Double) As Boolean
        If Not _Initialized Then Return False
        If Double.IsNaN(vl) OrElse Double.IsInfinity(vl) Then Return False
 
        Dim ivl As Double = vl
        'Ausreisser-Werte "einfangen"
        ivl = Math.Min(ivl, MyBase.ChartAreas(0).AxisY.Maximum)
        ivl = Math.Max(ivl, MyBase.ChartAreas(0).AxisY.Minimum)
 
        With MyBase.Series(cDataSeries)
            'Datenpunkt anhängen (incl. Zeitstempel)
            .Points.AddXY(DateTime.Now.Ticks - _starttime, ivl)
            If _createdatalist Then
                DataList.Add(New strucChartData With {.time = Now, .value = vl})
            End If
 
            'veraltete Punkte entfernen 
            While .Points.Count > _maxpoints
                .Points.RemoveAt(0)
            End While
            'X-Achse auf den aktuellen Abschnitt der Zeitlinie ausrichten
            MyBase.ChartAreas(0).AxisX.Minimum = .Points(0).XValue
            MyBase.ChartAreas(0).AxisX.Maximum = .Points(.Points.Count - _
              1).XValue
 
            'angehängten Datenpunkt einrichten
            With .Points(.Points.Count - 1)
                .AxisLabel = CStr(CLng(.XValue / cTicksPerSecond)) & " sec."
                If _showvaluelabel Then
                    .Label = CStr(Math.Round(ivl, 3))
                    .IsValueShownAsLabel = True
                End If
                If Not _showmarker Then
                    .MarkerStyle = Charting.MarkerStyle.None
                Else
                    .MarkerStyle = Charting.MarkerStyle.Cross
                    .MarkerSize = 10 : .MarkerColor = Drawing.Color.Black
                    If ivl <> vl Then .MarkerColor = Drawing.Color.Red _
                      'Ausreisser-Wert
                End If
            End With
        End With
 
        'Neuzeichnen des Chart veranlassen
        Me.Invalidate()
        Return True
    End Function
 
    ''' <summary>Abfrage aller Datenpunkte, falls die Liste angefordert 
    ' worden ist</summary>
    Public ReadOnly Property GetAllData() As strucChartData()
        Get
            If Not _createdatalist Then Return Nothing
            Dim DataArray(DataList.Count - 1) As strucChartData
            DataList.CopyTo(DataArray)
            Return DataArray
        End Get
    End Property
End Class