Public Class Universum
 
        'Nimm die übergebene Datei und parst sie
        'Speichert die gelesenen Werte in diesem Objekt ab
        Public Sub New(ByVal fileName As String)
            If String.IsNullOrEmpty(fileName) Then
                Throw New ArgumentNullException("fileName")
            End If
 
            If Not IO.File.Exists(fileName) Then
                Throw New IO.FileNotFoundException(fileName)
            End If
 
            Dim line As String
            Dim lines() As String = IO.File.ReadAllLines(fileName)
 
            For Each line In lines
                Dim cols() As String = line.Split("=")
 
                If cols.Length = 2 Then
 
                    Select Case cols(0).ToUpper.Trim()
                        Case "[UNIVERSUM]"
                            mUniversum = cols(1).Trim
                        Case "[SPIELERNAME]"
                            mSpielername = cols(1).Trim
                        Case "[METALL]"
                            mMetall = cols(1).Trim
                        Case "[KRISTALL]"
                            mKristall = cols(1).Trim
                        Case "[DEUTERIUM]"
                            mDeuterium = cols(1).Trim
                        Case "[DUNKLE MATERIE]"
                            mDunkleMaterie = cols(1).Trim
                        Case "[ENERGIE]"
                            mEnergie = cols(1).Trim
                    End Select
 
                End If
            Next
        End Sub
 
        Private mUniversum As String
        Private mSpielername As String
        Private mMetall As Integer
        Private mKristall As Integer
        Private mDeuterium As Integer
        Private mDunkleMaterie As Integer
        Private mEnergie As Integer
 
        Public ReadOnly Property Universum As String
            Get
                Return mUniversum
            End Get
        End Property
 
        Public ReadOnly Property Spielername As String
            Get
                Return mSpielername
            End Get
        End Property
 
        Public ReadOnly Property Metall As Integer
            Get
                Return mMetall
            End Get
        End Property
 
        Public ReadOnly Property Kristall As Integer
            Get
                Return mKristall
            End Get
        End Property
 
        Public ReadOnly Property Deuterium As Integer
            Get
                Return mDeuterium
            End Get
        End Property
 
        Public ReadOnly Property DunkleMaterie As Integer
            Get
                Return mDunkleMaterie
            End Get
        End Property
 
        Public ReadOnly Property Energie As Integer
            Get
                Return mEnergie
            End Get
        End Property
    End Class

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) _
      Handles Button1.Click
        Dim file As String
        Dim files() As String = IO.Directory.GetFiles("Pfad zum Verzeichnis", _
          "*.txt")
 
        'leeren der ComboBox
        ComboBox1.Items.Clear()
        'Eigenschaft des Objekts, das als Text angezeigt werden soll
        ComboBox1.DisplayMember = "Universum"
 
        For Each file In files
            'Pro Datei ein Universum Objekt erzeugen und hinzufüen
            ComboBox1.Items.Add(New Universum(file))
        Next
    End Sub

    Private Sub ComboBox1_SelectedIndexChanged(sender As Object, e As _
      System.EventArgs) Handles ComboBox1.SelectedIndexChanged
        'Abholen des selektierten Uni Objekts (wurde vorher hinzugefügt)
        Dim uni As Universum = CType(ComboBox1.SelectedItem, Universum)
 
        'Wenn es ein Uni Objekt ist, dann Spielername anzeigen
        'Es können hier auch alle anderen Werte wieder ausgelesen werden.
        If Not uni Is Nothing Then
            TextBox1.Text = uni.Spielername
        End If
    End Sub