Public Function GetTextLineEntries(ByVal Folder As String,
                    ByVal ParamArray Columnnames() As String) As DataTable
 
   'Tabelle mit den gewünschten Spalten erstellen
   Dim dt As New DataTable
   For i As Integer = 0 To Columnnames.Length - 1
      dt.Columns.Add(Columnnames(i), GetType(String))
   Next i
 
   With My.Computer.FileSystem
      For Each file As String In _
        .GetFiles(Folder, FileIO.SearchOption.SearchTopLevelOnly, "*.txt")
 
        'Zeilen in der Textdatei lesen
        Dim lines() As String = IO.File.ReadAllLines(file)
        'Neue Tabellenzeile erstellen
        Dim row As DataRow = dt.NewRow, rowtoadd As Boolean = False
        'Zeilen durchlaufen
        For Each line As String In lines
            line = line.Trim.ToUpper
            'In jeder Zeile nach den Spaltenbezeichnern suchen
            For i As Integer = 0 To Columnnames.Length - 1
               If line.Contains(Columnnames(i).Trim.ToUpper) Then
                  'Zeile aufspalten anhand des Gleichheitszeichens
                  Dim parts() As String = line.Split("="c)
                  If parts.Length = 2 Then
                    'Wert der Spalte in die Tabellenzeile eintragen
                    row(Columnnames(i)) = parts(1).Trim : rowtoadd = True
                  End If
               End If
            Next i
        Next line
        'ggf. die neue Zeile der Tabelle hinzufügen
        If rowtoadd Then dt.Rows.Add(row)
      Next file
    End With
    'Tabelle zurückgeben
    Return dt
 End Function

'Tabelle aus Dateien in einem Ordner erstellen
Dim dta As DataTable = GetTextLineEntries(<Pfadangabe>, "Universum", _
  "Spielername")
 
'Universum-Spalte der Tabelle an eine Combobox binden
ComboBox1.DisplayMember = "Universum"
ComboBox1.DataSource = dta
 
'Doe Spalte Spielername an eine Textbox binden
TextBox1.DataBindings.Add(New Binding("Text", dta, "Spielername"))