Public Class frmBindingDemo
 
    Dim dt As New DataTable     'Datenquelle
    Dim bs As New BindingSource 'Infrastruktur für Datenbindung 
 
 
    Dim WithEvents tbo As New TextBox With {.Parent = Me}
    Dim lbo As New ListBox With {.Parent = Me, .Top = 40, .Height = 100}
 
 
    Dim WithEvents btnSave As New Button With _
        {.Parent = Me, .Text = "&Speichern", .Top = 150}
 
 
    Private Sub frmTextBinding_Load(sender As System.Object, _
                         e As System.EventArgs) Handles MyBase.Load
 
        'Spalte für Texte 
        dt.Columns.Add("Texte", GetType(String))
 
        'Texte zeilenweise lesen (woher auch immer die kommen)
        Dim texte() As String = IO.File.ReadAllLines("C:\daten\demodaten.txt")
 
        'Datatable-Spalte mit Texten füllen
        For Each t As String In texte
            dt.Rows.Add(t)
        Next t
 
        'Bindingsource zwischen Texte und Controls
        bs.DataSource = dt
 
        'Datenbindung über Bindingsource herstellen
 
        'Bindung textbox
        tbo.DataBindings.Add("Text", bs, "Texte", True, _
                             DataSourceUpdateMode.OnPropertyChanged)
 
        'Bindung Liste
        lbo.DisplayMember = "Texte"
        lbo.DataSource = bs
    End Sub
 
 
    Private Sub btnSave_Click(sender As Object, e As System.EventArgs) _
        Handles btnSave.Click
 
        If dt.Rows.Count = 0 Then Exit Sub
 
        Dim texte(dt.Rows.Count - 1) As String
        For i As Integer = 0 To dt.Rows.Count - 1
            texte(i) = dt.Rows(i)("Texte").ToString
        Next i
 
        IO.File.WriteAllLines("C:\daten\demo_out.txt", texte)
 
    End Sub
 
    Private Sub tbo_KeyDown(sender As Object, _
        e As System.Windows.Forms.KeyEventArgs) Handles tbo.KeyDown
 
        'return-Taste in Textbox schließt Edit ab und aktualisiert den 
        'angezeigten Listeneintrag
        If e.KeyCode = Keys.Return Then bs.EndEdit()
    End Sub
End Class