''' <summary>Linie unter Einbezug einer Rotation zeichnen</summary>
''' <param name="gr">Graphics-Objekt für die Zeichnung</param>
''' <param name="line_start">Punkt definiert den Beginn der Linie (ohne 
' Rotation)</param>
''' <param name="line_end">Punkt definiert das Ende der Linie (ohne 
' Rotation)</param>
''' <param name="line_color">Farbe der Linie</param>
''' <param name="line_width">Breite der Linie</param>
''' <param name="rotation_center">Zentrum der Rotation (bei 0/0 Mitte der 
' Linie)</param>
''' <param name="line_angle">Drehwinkel im Uhrzeigersinn (in Grad)</param>
Private Sub DrawLine(gr As Graphics, line_start As Point, line_end As Point, _
                     ByVal line_color As Color, _
            Optional ByVal line_width As Integer = 1, _
            Optional ByVal rotation_center As Point = Nothing, _
            Optional ByVal line_angle As Double = 0)
 
        Using path As New System.Drawing.Drawing2D.GraphicsPath, _
            rotatematrix As New Drawing2D.Matrix, _
            line_pen As New Pen(line_color, line_width)
 
            path.AddLine(line_start, line_end)
 
            If rotation_center = Nothing Then
                rotation_center.X = _
                     line_start.X + (line_end.X - line_start.X) \ 2
                rotation_center.Y = _
                     line_start.Y + (line_end.Y - line_start.Y) \ 2
            End If
 
            rotatematrix.RotateAt(CSng(line_angle), rotation_center)
            path.Transform(rotatematrix)
            gr.DrawPath(line_pen, path)
        End Using
    End Sub